label chapter_12D:
    #Let's all go to the Aquarium
    scene black
    pause 2.5

    play music "audio/OST/west_coast_kicking.ogg" fadein 1.0
    "Every day after school for the next few weeks I would join Fang to help her practice."

    "Some days we would go to her place, and other days her father was home early."

    "Those days Fang would ‘politely ask’ Naser to drop her off at my place."

    "The bribes to keep it from her dad stopped being necessary after the third time."

    "The practice sessions themselves were long and arduous."

    "Sessions would go on until either her dad kicked me out or sundown."

    "Fang would play for hours on end, occasionally stopping to let me try and to take a break."

    "Despite my warnings, she’d play until her fingertips were red and raw."

    "I decided it was time for a real break once I ran out of band aids."

    "My great idea was to take out the map of the city I’d had since I moved in and throw a dart at it to decide where we’d go for the day."

    "There’s lots of neat places in the city for dates, the mall, the arcade, a local amusement park."
    pause 0.5
    "...And the dart landed in the ocean over the dock."

    "The look from Fang told me she wasn’t stepping anywhere near a tuna boat."

    "The Aquarium it is."

    scene aquarium with fade

    "So here we are inside after paying admission."

    "I’d suggested she wear some gloves, just to protect her hands."

    "I don’t think she understood the second part, because they were fingerless."

    "The Aquarium is a large marble building on a marina."

    "The various exhibits sprawl out to make the place turtle-shaped from a birds-eye view."

    "It’s a nice place, but I still need to make this entertaining to Fang."

    "She already looks bored."

    "Looking through one of the map kiosks, I try to make a mental plan for the trip."

    show fang neutral at scenter:
    show anon neutral at aleft:
        xalign 0.1
    with dissolve

    A "Uhh{cps=*0.1}...{/cps} {w=0.2}They got exhibits for the deep sea, the gulf of Mexico, the dopefish, tropical reefs{cps=*0.1}...{/cps}"

    A "{cps=*0.1}...{/cps}Eenie{w=0.15} meanie{w=0.15} mini-"

    F "Really?"

    A "Sea turtles it is."

    show fang:
        pause .6
        "fang happy" with dissolve
        easein_cubic 1 xalign 0.4
    show anon:
        easeout_cubic 0.5 xalign 0.225 #0.35
        pause .1
        easein_cubic 1 xalign 0.175 #0.725

    "I take Fang’s hand and lead her through the lobby into the chamber labeled ‘Sea Turtle Conservatory’."

    show fang:
        #"fang happy"
        xalign 0.4
        ease_cubic 3.1 xalign 1.65+1.8+0.6
    show fang happy
    show anon:
        xalign 0.175
        ease_cubic 3.1 xalign 1.85+0.5 #0.725

    window hide
    window auto

    pause 1.5
    scene black with dissolve
    pause .5
    scene aquariumexhibit with dissolve


    show fang happy:
        xalign -1.8
        ease_cubic 2.4 xalign 0.625
        pause .1
        "fang very happy" with dissolve
        ease_cubic 0.4 xalign 0.680
    show anon neutral:
        xalign -1.8
        ease_cubic 2.412 xalign 0.225 #0.625

    pause .2

    F "Anon, are you sure you want to spend the day here? {w=.2} If you wanted to go to the mall or somethin- {cps=*2.0}omigawd.{/cps}"

    "A little sea turtle swims out of hiding in the tank right in front of us."

    show fang:
        "fang very happy"
        "fang adorable" with dissolve
        block:
            parallel:
                easeout_cubic 0.05 yalign -0.04
                ease_cubic 0.5 yalign 0.1
                ease_cubic 0.3 yalign 0.0
            parallel:
                pause 0.12
                ease_cubic 0.4 xalign 0.8
                ease_cubic 1.2 xalign 1.8
#pause 0.0001
    show fang adorable with dissolve

    "Immediately Fang breaks free of my arm and presses against the glass."

    F "Look at these cute little shits, I love them!"

    show fang adorable at sleft:
        xalign 1.8
        "fang adorable" with dissolve
        easeout_cubic 0.1 yalign -0.04
        ease_cubic 0.5 yalign 0.1
        ease_cubic 0.3 yalign 0.0
    show anon:
        xalign 0.225

    A "Yeah, I see them."

    show fang adorable:
        yalign 0.0

    show anon neutral:
        ease_cubic 1.95 xalign 0.87

    "I peer into the tank and see a few more hatchlings bob out of the decorative grass."

    "The hype becomes contagious and I find myself pressed against the glass as well."

    Attendant "Please avoid touching the glass, it stresses the little guys out."

    A "Oh, sorry."

    A "Come on Fang, there’s more stuff to see."

    show fang sad flip with dissolve

    F "{cps=*0.75}Nnnnnnnnnnnnnnnnnnnnnnnnnno{/cps}."

    A "There’s more here than just those baby turtles, you know."

    F "Doesn’t matter."

    A "You’re just going to stay here all day then?"

    F "{cps=*0.75}NYyyeeeep.{/cps}"

    show fang happy with dissolve

    A "What’ll you do for lunch?"

    F "Bring me something from the cafe."

    show anon neutral flip with dissolve

    A "Allright, here I am going off without you."

    show anon:
        "anon neutral flip"
        ease_cubic 0.8 xalign 0.7
        pause .2
        "anon grin flip" with dissolve

    A "{w=.5}Oh look, {w=.5} a Dumbo Octopus."

    F "{cps=*2.0}Whereisit?{/cps}"

    show fang happy flip with dissolve

    "In a snap Fang’s moved from pressing her face against the turtle tank to pressing it against the octopus tank."

    #scene aquariumexhibit
    #intentional ghost / meteor walk
    show fang happy flip:
        ease_cubic 0.6 xalign 0.1
    with dissolve
    show anon neutral flip with dissolve

    #confirmed that fang has autism
    Attendant "Ma’am, please refrain from-"

    show fang adorable flip at sleft with dissolve# at sleft

    F "{cps=*1.5}OmigoshAnonlookatit.{/cps}"

    F "It’s like a living egg yolk with button eyes."

    A "Is that the first analogy you can think of{cps=*0.1}...{/cps}?"

    #Fang has the zoomies
    F "And what’s over there? Are those seahorses{cps=*1.5} holy crap I have to take a video of this.{/cps}"

    window hide
    window auto
    hide anon with dissolve

    scene aquariumexhibit

    show fang adorable at sleft with dissolve #at sleft
    #new method
    show fang:
        # yalign 0.0 xcenter 0.4
        block:
            parallel:
                ease_cubic 0.25 xzoom 1.0
            parallel:
                ease_cubic 0.5 zoom 0.75 ypos 0.1 xpos 0.6
        pause 1.0
        block:
            parallel:
                linear 0.25 xzoom -1.0
            parallel:
                ease_cubic 0.5 zoom 0.8 ypos 0.1 xpos -0.2
        pause 1.0
        ease_cubic 0.5 zoom 0.4 xpos 0.0 ypos 0.3
        pause 1.0
        block:
            parallel:
                linear 0.25 xzoom 1.0
            parallel:
                ease_cubic 0.5 zoom 1.0 xpos 0.2 ypos 0.1
        pause 1.0
        ease_cubic 0.5 zoom 0.3 xpos 0.65 ypos 0.33
        pause 1.0
        repeat

    pause 2.0
    "I shrug apologetically at the attendant who has given up entirely."

    "But watching Fang zoom between the exhibits to gush over each oddly cute sea animal was just too much."

    "Subtly my phone finds its way into my jacket pocket, already set to record."
    window hide
    window auto

    #show anonphone at scenter with easeinbottom
    show anonphone at scenter with easeinbottom #cursed

    "She’ll probably kill me if she found out."
    hide fang adorable with dissolve
    "But it’d be a good death."
    pause 0.5
    "Wait, where’d she go?"

    #hide anonphone with dissolve
    window hide
    window auto
    hide anonphone with easeoutbottom

    pause .25
    scene black with dissolve
    pause 0.5
    scene stingray pool with dissolve

    "I round the corner to see the next room has a large group of school children hovering over a stingray touch tank."
    "That is, a large group of school children and Fang, towering above the rest."

    "She does have the act down though."

    A "Oh, cool, a stingray pool."

    A "You plan on touching one?"

    F "Touch?"

    A "Yeah, you can put your hand in and they’ll slide against it, watch."

    "I roll up my jacket sleeve and push my hand into the water, splaying it out."

    "Fang and the children lean in intently."

    "The water’s cold, but sure enough, a few of the playful things make their round and slide up right against it like a cat begging for scratches."

    A "See?"

    "Several in the crowd start jumping with excitement and put their own hands in the water to try for themselves."

    "Fang doesn’t seem completely convinced, though."

    F "You sure they’re alright to just touch like that?{w=0.2} Aren't those dangerous?"

    A "I mean, it’s a bit slimy, but there’s a hand sanitizer thing on the wall right there."

    F "That isn’t what I meant."

    A "Come on, I’ll make sure they don’t bite."

    "Fang reluctantly grabs my dry arm and I lead her to a spot not occupied by ankle biters."

    "I put my hand back in and motion for Fang to do the same."

    "She hesitates with her hand raised just above the waters’ surface, then plunges her hand down next to mine."

    "It doesn’t take long for a few rays to make the corner and brush up against our hands."

    F "Eep!"

    A "You alright?"

    F "Yeah, no, it’s just{cps=*0.1}...{/cps} You were right about them being slimy."

    A "Well, I have yet to hear of a dry fish."

    F "Shut up."

    "After a few more rounds of rays, Fang decides she’s had enough."

    scene black with dissolve
    pause 0.5
    scene aquarium

    show anon neutral at aleft
    show fang happy flip at sright
    with dissolve
    A "See, that wasn’t terrible, right?"

    A "Actually, you got all your fingers right?"

    F "I dunno, wanna check?"

    show fang flip off happy flip with dissolve

    "Her cheeky grin and raised middle finger confirm her hand’s integrity."

    show fang neutral flip with dissolve

    F "So uh{cps=*0.1}...{/cps}"

    F "Which exhibit are we checking next?"

    "I check the aquarium pamphlet to see where we haven’t been yet."

    A "Well... if we go outside we can see the dolphin pools. That way it loops back through the deep sea exhibits."

    "With Fang in agreement I lead her towards the exit marked with a large dolphin sign."
    stop music fadeout 3

    scene black with dissolve
    pause 0.75
    scene aquariumoutside with dissolve

    "Upon exiting the building my nose is assaulted by a mix of salty air and the smell of raw fish."

    "Somehow it’s even fishier than inside the aquarium."
    play music "audio/OST/Bayside Bumming it.ogg" fadein 1.0

    show fang happy at sleft
    show anon neutral flip at aright
    with dissolve

    F "Ooh, smells like lunch."

    A "It says they should be feeding the dolphins pretty soon."

    "The walkway circles around a large pool with several dolphins swimming around, and I can make out the trainer holding a hoop with a bucket of fish by their feet."

    "One of the dolphins jumps straight through the hoop and is rewarded with a fish caught out of the air."

    F "Would you jump through a hoola hoop for me if I had treats?"

    A "{cps=*0.1}...{/cps}"

    "I notice the trainer has traded the hoop for a large brush and is getting one of the dolphins to open its mouth."

    "The trainer starts brushing the Dolphin’s teeth and showing off the rows of neatly spaced cones."

    "I make a show of craning my neck down to get a view of Fang’s teeth from below."

    "She raises an eyebrow for a second and then realizes."

    #god elbow worse than her standing jab? lmao
    show fang neutral with dissolve
    show fang:
        "fang angry" with dissolve
        ease_cubic 0.6 xalign 1.0
        parallel:
            easein_cubic 0.9 xalign 0.3
        parallel:
            block:
                pause 1.1
                "fang embarass" with dissolve
                pause 1.4
                "fang sad" with dissolve

    show anon:
        pause .62
        ease_cubic 0.25 xalign 1.02
        ease_cubic 0.35 xalign 1.0

    "An elbow jams into my shoulder and her other hand covers her snout."

    pause .5

    A "So that’s how you brush your teeth!"

    show fang considering with dissolve

    F "{cps=*0.1}...{/cps}I don’t need someone to bribe me at least."

    A "Well if you ever need help I’m sure I can get them to lend me one of those brushes."

    show fang angry with dissolve
    show fang:
        "fang angry" with dissolve
        ease_cubic 0.5 xalign 1.0
        ease_cubic 0.5 xalign 0.5
        "fang neutral" with dissolve

    show anon:
        pause .5
        "anon ohshit flip" #
        ease_cubic 0.25 xalign 1.1
        "anon neutral flip" with dissolve
        ease_cubic 0.35 xalign 1.0

    "And that gets me a jab to the ribs this time."

    show anon neutral flip with dissolve

    A "Oh come on, you have to admit they look a bit like you..."

    F "Ehh, I don’t see it."

    "The dolphin beside her nods in agreement."

    "{cps=*.1}...{/cps}Right then{cps=*.1}...{/cps}"

    show fang happy with dissolve

    A "So, how bout we hit the last spot and then go grab our own lunch?"

    A "Unless you want to have some tuna with your clone there."

    show fang considering with dissolve

    "Fang rolls her eyes at that."

    "Her dolphin duplicate did too."

    A "You’re fucking with me,{w=0.2} aren’t you."

    show fang neutral with dissolve

    F "What’re you talking about?"

    "Fang’s aquatic doppelganger makes a laugh-like chirping and finally swims away."

    "{cps=*.1}...{/cps}"

    A "So Deep Sea then!"

    scene black with dissolve

    pause .5

    "We leave the dolphin pen, following signs back towards the building."

    "The floor slopes slowly until we reach a door labelled as the sub-level to our destination."

    "Pushing through, we find ourselves in an oversized hamster tube beneath the water."

    "Oh, I didn’t realize they had one of these."

    pause .25

    scene aquariumtube with dissolve

    "From within the glass walkway we’re surrounded by a myriad of colorful marine life swimming around us."
    show fang surprised at sright
    show anon neutral at aleft
    with dissolve

    "Fang’s eyes are wide as she tries to follow the different schools of fish that dart to and fro about."

    "I’m more mesmerized by the water filtered light cascading off Fang, casting her in a gentle glow that illuminates her white feathers."

    "God.{w=0.2} So glad I’m recording this."

    F "Recording what?"

    #show fang  flip with dissolve
    show fang neutral flip with dissolve

    A "The uh{cps=*0.1}...{/cps}{w=0.1} {cps=*2.0}The shark!{/cps} Yeah, that cool looking shark over there!"

    show anon neutral flip with dissolve

    "I point to the shark that’s currently lazing about, casually drifting by the walkway."

    show anon:
        pause .4
        ease_cubic 0.8 xalign 0.5
    show anon neutral with dissolve

    show fang:
        ease_cubic 1.1 xalign -0.3
    show fang adorable flip with dissolve

    "Fang turns to gush at the shark, giving me the opportunity to quickly stop my phone and see that my battery is near dead and storage near full."

    A "Ah, there’s the last exhibit."

    show fang happy with dissolve

    "I hold open another set of doors, the room within near pitch black."

    F "Is it closed?"

    A "Hm?"

    F "The lights{cps=*.1}...{/cps}"

    A "Oh! Nah, the room is dark because the things inside aren’t used to light."

    show fang neutral with dissolve

    F "O-oh."

    show anon flip with dissolve

    A "Wait{cps=*.1}...{/cps}{w=0.2} are you sca-"

    show fang sad with dissolve

    F "No! I just{cps=*.1}...{/cps}{w=0.2} Wasn’t expecting it, is all."

    show anon neutral:
        ease_cubic 1.0 xalign 0.39
        ease_cubic 0.65 xalign 0.45
        "anon face happy" with dissolve
    show fang:
#pause 1.2
        pause 0.95
        ease_cubic 0.8 xalign -0.19
        "fang happy" with dissolve

    "I offer her my hand."

    "Despite her claim otherwise I can feel how tense she is by how her fingernails dig into my hand."

    show anon:
        "anon face happy"
        ease_cubic 1.8 xalign 2.8
    show fang:
        "fang happy"
        ease_cubic 1.8 xalign 3.6

    pause .5
    stop music fadeout 2
    scene black with dissolve

    "I lead her into the darkened room, what little light there is coming from the various animals within."
    play music "audio/OST/Beach Chill Out.ogg" fadein 1.0


    "The aquariums within are packed with bioluminescent jellyfish, illuminating the darkened room with an ethereal glow."
    scene jellyfishroom with dissolve

    F "Whoa. This is{cps=*.1}...{/cps}"

    A "Beautiful."

    F "Yeah{cps=*.1}...{/cps}{w=0.3} that{cps=*.1}...{/cps}"

    "I wasn’t referring to the exhibit."

    "Fang’s grip on my hand eases, and her fingers work to intertwine with mine."

    "With what little light there is I can make out Fang’s smile."

    "My eyes have adjusted enough that I can see Fang’s eyes locked onto mine, the gossamer light making them glow."

    "My lips press softly onto Fang’s beak-end in a chaste peck."

    F "Eep!"

    F "Oi! G-give me a warning next time!"

    A "Mmmm{cps=*0.1}...{/cps} Naaaah."

    "I laugh even as her hip bumps me roughly."

    "Our interlocked fingers prevent her from using her preferred elbow tactic."

    A "So{cps=*0.1}...{/cps}{w=0.05} had fun?"

    F "Mmmm{cps=*0.12}...{/cps}{w=0.05}Maaaaybe{cps=*0.12}...{/cps}"

    F "I’ll say yes if you delete that recording."

    A "Awwww, but you were so cute!"

    F "Sh-shut up! I’m sexy damn it! Not cute!"

    A "Why not both?"

    "She glowers."

    pause .5

    A "Feel rested?"

    F "A bit. I’ll feel even more rested after some lunch though."

    A "Sounds like a plan."
    window hide
    window auto
    pause .25

    scene aquariumoutside with Dissolve(1.25)
    pause .5
    "The rest of our rest day was spent just relaxing on the pier."

    "Snacks on the boardwalk."

    "A bad sunburn on my neck."

    "And a very relaxed girlfriend."

    "Overall,{w=0.2} mission successful."

    pause 0.5
    "Except the sunburn."

    "Ow."

    stop music fadeout 3.0
    scene black with Dissolve(1.5)
    #pause .5

    #"{cps=*0.1}...{/cps}"
    window hide
    window auto
    pause 1

    return