label chapter_9:
    #VVURM DRAMA
    label bdebug:
    pause 1

    play music 'audio/OST/Fuck You I Like This Chick.ogg' fadein 2.0
    scene hallway with Dissolve(1.5)
    pause .5

    "End of midterms means the start of the new quarter."

    "Halfway through the semester, and things have been going pretty good."

    "I didn’t completely fuck up so far, and I think the rest of the band is starting to warm up to me."

    "Especially Fang."

    "In fact we’ve been hanging out more in the auditorium after school."

    "Instead of band practice we’ve been making use of that repaired projector."

    "Watching shitty movies and playing games on Reed’s Xrox."

    window hide
    window auto
    pause .5

    N "Why are you so deep in thought, Anon?"

    window hide
    window auto
    show naomi neutral at scenter with dissolve
    pause .5

    "The Mandarin Manchurian rips me away from my monologue."

    "During homeroom, Spears came on the announcement to declare an assembly for the senior class."

    "Or in his own words,"

    Sp "{alpha=.75}{i}\"ASSES IN THOSE SEATS NOW!\"{/i}{/alpha}"

    window hide
    window auto
    pause .5

    show naomi:
        easein_cubic 1.5 xalign 0.3
    show anon neutral with dissolve:
        xalign 1.0 yalign 0.1
        easein_cubic 1.5 xalign 0.75  
    pause 1

    "Naomi has taken the opportunity to walk with me through the hallways."
    pause .5

    A "What do you want?"

    show naomi explanatory with Dissolve(.25)
    N "So I heard you and Fang went on another date the other day."
    show naomi neutral with Dissolve(.25)

    "Of course she did."

    A "It wasn’t a date, we were just hanging out."

    "Just kickin’ Reed’s ass in Rock Ring 3."

    "Pls give mammoth bone armor."
    pause .25

    show anon behind naomi
    show anon shrug flip with dissolve
    A "You do anything fun with Naser lately?"

    show naomi explanatory with Dissolve(.25)
    N "OH! {w=0.3}{nw}"
    show naomi:
        ease 0.2 yalign 0.05
        ease 0.4 yalign 0.0
        repeat 2
    extend "My Naser just had another track meet!"

    show naomi neutral
    show anon neutral flip 
    with dissolve

    "That always works."

    show naomi happy with Dissolve(.25)
    N "His high jump form is so perfect!"

    N "And he looks so dazzling in his track and field uniform!"

    show naomi:
        ease 0.75 xalign 0.315
        ease 0.75 xalign 0.285
        repeat
    N "{cps=*.1}...{/cps}And his physique{cps=*.1}...{/cps}"

    "I tune her out as she covers her profusely red nose."

    show naomi:
        ease 0.75 xalign 0.3

    "The less I can think of Naser’s body the better."

    stop music fadeout 4
    window hide
    window auto

    play ambient 'audio/effects/teenageCrowdFarLoop.ogg' fadein 3
    scene auditorium with Fade(1,0.5,1)
    pause .5

    "We get to the auditorium once again and I look to the back row to find our spot."
    pause .5

    "Empty?"
    window hide
    window auto
    pause .5

    play music 'audio/OST/Dragging on and on....ogg' fadein 1.0
    stop ambient fadeout 3
    F "OVER HERE, ANON!!"

    window hide
    window auto
    pause .5

    show reed neutral:
        yalign 0.1 xalign 1.15 #1.35
    show trish considering:
        yalign 0.0 xalign 0.65
    show fang neutral:
        yalign 0.0 xalign 0.25
    with Dissolve(1)
    pause .5

    "Fang and Trish are sitting in the front row."

    "Next to them is Reed huddling behind a cart with the projector he’d fixed on it, messing with the cords."
    window hide
    window auto

    show anon neutral with dissolve:
        yalign 0.1 xalign -0.5
        easein_cubic 1 xalign -0.3
    pause 1

    A "What’s the deal? Why are we sitting in the front all of a sudden?"

    show reed explanatory flip with dissolve:
        xalign 1.4
    Re "{cps=*.25}Uhhhh{/cps}{cps=*.1}...{/cps} Spears asked me to man the projector{cps=*.1}...{/cps}"

    Re "First I was like \"say {cps=*.25}whaaaaat{/cps}\", but then I was like \"yeah, man, sure\"."

    Re "So here I am."

    show reed neutral flip with dissolve

    A "I{cps=*.1}...{/cps} see{cps=*.1}...{/cps}"
    pause .5

    show anon:
        easeout 0.5 xalign -0.1
        easein_back 0.5 xalign -0.05

    "I take my seat next to Fang."
    pause .5

    A "They say why we’re here yet?"

    show fang unimpressed with Dissolve(.25)
    F "Nope."

    show trish neutral with Dissolve(.25)
    T "Since we’re seniors it’s probably some other stupid pep talk about ‘Our Futures’."

    show reed explanatory flip with Dissolve(.25)
    Re "I bet it’s a fundraiser{cps=*.1}...{/cps}"

    Re "I’m like, good at selling things and stuff{cps=*.1}...{/cps}"
    show reed neutral flip with Dissolve(.25)

    A "I’m sure."
    pause .5

    A "Actually, I’ve been meaning to ask."

    A "What exactly is 'carfe'?"

    show reed shocked flip with Dissolve(.25)
    Re "You don’t know man?"

    show reed explanatory flip with Dissolve(.25)
    Re "Carfentanyl.{w=.3} The wildest stuff a dino can get."
    show reed neutral flip with Dissolve(.25)

    A "Really now?"

    show trish explanatory with Dissolve(.25)
    T "It was used in war by skinnies a while back. It’s a deadly tranquilizing agent."
    
    show trish neutral
    show reed considering flip
    with Dissolve(.25)

    Re "It’s only deadly when you make it wrong, man."

    show reed explanatory flip with Dissolve(.25)
    Re "But yeah, it’s great stuff if you know how to do it."
    show reed neutral flip with Dissolve(.25)
    pause .5

    A "Fang, have you ever tried any?"
    
    show fang considering with Dissolve(.25)
    F "Once."

    F "Woke up hanging upside down from a tree with Naomi’s clothes on hugging a fake skeleton."
    pause .5

    T "See, when I do it it just makes me a bit dizzy for a few hours."

    A "Huh.{w=0.3} Can I see some?"

    show reed considering flip with Dissolve(.25)
    Re "Absolutely not."

    F "No."

    show anon shrug with Dissolve(.25)
    A "Why not?"

    show trish considering with Dissolve(.25)
    T "That stuff’s a hundred times more powerful than horse tranquilizer."

    T "It’d melt your skin."

    show reed explanatory flip with Dissolve(.25)
    Re "Make your heart burst."
    show reed neutral flip with Dissolve(.25)

    F "I heard a human tried it once and exploded."

    T "I bet."

    show anon:
        "anon neutral" with dissolve
    A "Yeah, yeah, sure. You just don’t want to share."

    show trish neutral
    show fang happy
    with dissolve

    "The last of the seniors trickle in and take seats near the front."

    "Eventually Spears takes the stage."
    window hide
    window auto

    hide reed
    hide anon
    hide trish
    hide fang
    with Dissolve(1)
    pause .5

    show spears neutral flip at scenter with dissolve:
        xalign 1.5
        easein_cubic 1 xalign 0.5
    pause 1
    stop music fadeout 3.0
    "He pauses to make sure everyone’s covering their ears before beginning."

    window hide
    window auto
    pause .5

    show spears angry flip with Dissolve(.25)
    play sound 'audio/effects/spearYellRumbleVoice.ogg'
    window show Dissolve(0.0001)
    Sp "{cps=*.25}ALLLRIGHT{/cps}!" with vpunch

    show spears neutral flip with dissolve
    Sp "AS YOU ALL KNOW, GRADUATION’S COMING UP SOON."

    Sp "WE’RE GOING TO GO OVER THAT WHOLE PROCESS,"

    Sp "BUT FIRST THE STUDENT COUNCIL HAS A BRIEF PRESENTATION TO GIVE ON THE SUBJECT."
    pause .5

    Sp "FLOOR’S ALL YOURS, STUCO."
    window hide
    window auto
    show dimmer_darker behind spears with Dissolve(1)
    pause .5

    play music 'audio/OST/The Top of the Social Ladder.ogg' fadein 2.0
    show spears neutral flip:
        xalign 0.5
        easeout_cubic 1 xalign 1.0
    pause .5
    hide spears with dissolve
    pause .25

    show naomi neutral flip with dissolve:
        xalign 1.5
        easein_cubic 1 xalign 0.8

    "Spears gestures his hand towards Naomi and Naser, who show up from behind the stage curtains."

    "The Chiffon Czarina brings a wireless microphone to her snout."

    "She begins reciting a well rehearsed speech in her usual snooty{w=.2} (heh){w=.2} manner."
    pause .5

    "More plastic than person."

    show naomi happy flip with dissolve
    N "Why, thank you, Principal Spears!"
    show naomi neutral flip with dissolve

    "The projector comes to life, displaying a basic slideshow title card reading."
    pause .5

    A "Reed, how do you know when to move it forward?"

    Re "It’s when she crosses her fingers. Check it out."

    show naomi explanatory flip with Dissolve(.25)
    N "Now, this is a very important turning point in your life!"
    show naomi neutral flip with Dissolve(.25)
    pause .5

    "Ah, got it, It’s one of these. I needed a nap."
    pause .5
    
    scene black with dissolve
    pause .5

    "As soon as I closed my eyes I felt a malevolent force looming before me."

    "Somehow, I felt like opening my eyes was a bad idea."

    "But keeping them closed was an even worse one."
    window hide
    window auto
    
    scene projector1 with Dissolve(1)
    pause .5

    "At least there’s cute little designs on the slides."

    "There’s a little penguin with a graduation cap{cps=*.1}...{/cps}"

    scene projector2 with dissolve

    "There’s the school mascot in a party hat{cps=*.1}...{/cps} even has the fogged up window{cps=*.1}...{/cps}"

    scene projector3 with dissolve

    "A lineup of various graduates with a token human at the end for diversity. Typical."

    scene projector4 with dissolve

    "There’s some scientists and engineers holding hands{cps=*.1}...{/cps}"

    scene projector5 with dissolve

    "There’s a triceratops holding onto a branch with the text \"Hang in there, baby!\""

    scene projector6 with dissolve

    "There’s me two years ago when I photoshopped myself with an anime girl."

    window hide Dissolve(0.001)
    window auto
    $ renpy.music.set_volume(0, 0.02, 'music')
    stop music fadeout 0.2
    scene projector7 with Dissolve(.25)
    pause 2

    "{cps=*.1}...{/cps}"

    "{cps=*.1}....{/cps}"

    "{cps=*.1}.....{/cps}"
    window hide
    window auto
    pause 2

    $ renpy.music.set_volume(1, 0, 'music')
    play music 'audio/OST/you can_t sage here.ogg' fadein 1.0
    "{i}What the fuck-{/i}"

    "{i}HOW!{/i}"

    "{i}{b}WHY!{/b}{/i}"

    "The world’s stopped turning.{w=.3} No one around me is moving and there is no sound at all."

    "Why is that here?{w=0.4} {i}How!{/i}" 
    
    "I deleted everything!{w=.4} {i}EVERYTHING!{/i}"

    "{i}So why the fuck is it here.{/i}"
    pause .5

    "My body feels like stone as I try to turn."

    "To see if anyone else is seeing this."

    "In the end I can’t bring myself to move at all."

    "It doesn’t matter, I already feel their endless gazes."

    camera:
        linear 5 blur 30
    show dimmer_darker:
        alpha 0
        block:
            ease_cubic 2 alpha 1.0
            ease_cubic 2 alpha 0.0
            repeat

    "I feel lightheaded."

    "There’s what feels like a lump of lead in the pit of my stomach."

    "There’s dark spots forming in my sight."

    "When I finally breathe again the world restarts."

    "The laughter hits first."

    "A monstrous guffaw from behind, that’s joined by every other senior in the room."
    camera:
        linear 0.5 blur 0
    show dimmer_darker:
        linear 0.5 alpha 0
    play ambient 'audio/effects/teenageCrowdJeerLoop.ogg' fadein 3
    play sound 'audio/effects/teenageCrowdLaugh.ogg'
    window hide
    window auto
    pause 1.5

    show naser shocked flip:
        yalign -0.5 xcenter 1.5
        easein_cubic 1 xalign 1.4
    Nas "REED CHANGE THE SLIDE,{w=.3} CHANGE IT NOW!"

    show reed shocked:
        yalign -0.5 xcenter -0.7
        easein_cubic 1 xalign -0.5
    Re "I-{w=.2}I am!"

    show projector8 behind reed, naser with Dissolve(.25)
    "More pictures."
    
    "So many more pictures."
    show projector9_blur behind reed, naser with Dissolve(.25)

    "Each one more and more embarrassing than the last."
    pause .5

    "I{cps=*.1}...{/cps} oh god{cps=*.1}...{/cps}"
    window hide
    window auto
    pause .5

    show naser angry flip with Dissolve(.25)
    Nas "Shit!"

    window hide
    window auto
    pause .5

    show naser:
        easein_quart 0.5 xcenter 0.8
    pause .25
    show naser table hit
    show white:
        alpha 1
        pause .1
        alpha 0
        linear 0.5 alpha 1
    play sound 'audio/effects/tableslam.ogg'
    with vpunch
    play audio 'audio/effects/slapstickglassbreak.ogg'

    show black with Fade(0.14, 0, 0, color="#fff")

    stop music
    stop ambient fadeout 5
    #show black with Fade(0, 1, 3, color="#fff")
    pause .5
    "There’s a loud crash right next to me and the entire room becomes black."
    pause .5

    "Did I faint?"

    "Is this real life?{w=0.5} Is this just fantasy?"
    window hide
    window auto
    pause 1

    F "A-Anon?"
    pause .5

    "Still awake.{w=0.4} Fuck."
    window hide
    window auto
    pause .5

    play ambient 'audio/effects/teenageCrowdJeerLoop.ogg' fadein 3 volume 0.5
    play ambient1 'audio/effects/teenageCrowdFarLoop.ogg' fadein 1
    scene auditorium
    show dimmer_light
    show fang shocked:
        yalign 0.0 xcenter 0.6
    show anon sad:
        yalign -0.1 xcenter 0.4
    show reed shocked flip:
        yalign 0.1 xcenter 0.95
    show naser annoyed:
        yalign 0.1 xcenter 0.15
    with Fade(0.5, 0, 1.5, color="#fff")
    pause .5

    "The lights come back on and my eyes burn."

    "The projector is on the floor, lens shards scattered all around."

    "The laughter is even louder now."
    
    show naser angry with Dissolve(.25)
    Nas "Reed how the {i}fuck{/i} did this happen?"

    Re "L-{w=.2}look I just used the USB Trish said-"

    show naser:
        easein_quart 1 xcenter 0.2
    show naser surprised with Dissolve(.25)
    Nas "{cps=*2.0}TRISH?!{/cps}{w=0.4} Why would Trish-"

    "Trish{cps=*.1}...{/cps}{w=0.3} wasn’t in her seat."

    "In the corner of my eye I notice someone running for the entrance."

    "It’s Trish.{w=.3} She’s making a mad sprint for the door."

    show naser angry with Dissolve(.25)
    Nas "Stop her!{cps=*.1}...{/cps}"

    show naser:
        parallel:
            easeout_cubic 0.75 xcenter 0.9
        parallel:
            pause .25
            linear 0.5 alpha 0
    pause .5
    show reed considering flip:
        parallel:
            easeout_back 0.75 xcenter 1.4
        parallel:
            pause .25
            linear 0.5 alpha 0

    "She continues dashing towards the exit{cps=*.1}...{/cps}"

    "And right into Spears’ hand."

    "Literally."

    show fang surprised with dissolve

    "His baseball mitt of a hand covers the{cps=*.1}...{/cps}{w=0.1} the{cps=*.1}...{/cps}{w=0.1} {i}that fucking {b}BITCH!{/b}{/i}"

    "Covers her face entirely."

    "Even lifts her up. By her face. With one hand."

    play sound 'audio/effects/spearYellRumbleVoice.ogg'
    Sp "ALL OF YOU GET YOUR ASSES BACK TO CLASS." with vpunch

    "Spears motions for me to follow him but I feel paralyzed by everything that just happened."

    show fang sad with Dissolve(.25)

    "I bury my face in my hands and just groan."

    "This is Rock Bottom all over again."
    pause .5

    show anon:
        easein_back 1 xcenter 0.43
    show fang:
        easein_back 1 xcenter 0.625 
    with None
    show fang sad flip with Dissolve(.25)

    "Fang tugs at my arm, trying to get me to follow."

    "I just can’t find the energy to move anything right now."

    "Fang frantically looks around at the hysterical crowd, trying to come up with something."

    "Eventually, I feel Fang put her arm over my shoulder as she tries to get me to stand."

    show anon:
        easein_back 1 xcenter 0.5
    show fang:
        easein_back 1 xcenter 0.65
    with None
    show fang sad with dissolve
    "She drapes her wings across my back, creating a barrier between me and everyone else."

    show fang:
        easeout_cubic 1 xcenter 1.2
    show anon:
        easeout_cubic 1 xcenter 1.05
    pause .5
    hide fang
    hide anon
    with dissolve

    "Without saying a word she leads me out of a side door towards the principal’s office."
    stop ambient fadeout 4
    stop ambient1 fadeout 8

    window hide
    window auto
    pause .5

    scene black with Dissolve(1.5)
    pause .5

    "What the fuck just happened?"
    window hide
    window auto
    pause .5

    scene hallway
    show anon sad:
        yalign 0.1 xcenter 0.55
    show fang sad:
        yalign 0.0 xcenter 0.45
    with Dissolve(1.5)
    pause .5

    play music 'audio/OST/Beach Chill Out.ogg' fadein 1
    F "Hey{cps=*.1}...{/cps}"

    "How is this happening to me?"

    F "{cps=*.1}...{/cps}You gonna be alright?"

    "How did Trish find those dumb pictures?"

    F "Look, don’t listen to those pricks Anon."

    "Was Reed in on it?"

    F "All of them dumbasses."

    "He couldn’t be, what would he gain from something like this?"

    F "Like{cps=*.1}...{/cps} this’ll all blow over."

    "What would {i}Trish{/i} gain from something like this?"

    F "Like, none of them talk about our shitty concert."

    "I know she doesn’t like me but {i}this{/i}{cps=*.1}...{/cps}"

    F "And that was like, a fuckin’ month ago."

    "{cps=*.1}...{/cps}This is fucked up!"

    "I’m going to rip her stupid horns off and give her a couple new holes to breathe with!"

    F "It’ll be all good Anon."

    "Think Fang’s dad had a thing going on with the golf clubs{cps=*.1}...{/cps}"

    "See if he can give me a couple of pointers."

    F "Just needs some time to forget it happened."
    pause .5

    "The squeak of sneakers catches my attention and I turn to see Reed approaching us down the hall."
    window hide
    window auto

    show fang:
        easein_cubic 1 xcenter 0.55
    show anon:
        easein_cubic 1 xcenter 0.65
    with None
    show reed considering with dissolve:
        yalign 0.1 xcenter -0.2
        easein_cubic 1 xcenter 0.2

    pause .5
    
    show fang considering with Dissolve(.25)
    F "Reed{cps=*.1}..?{/cps} I thought Spears sent everyone back to class."

    Re "Can't just sit in class while all my hombres are going through some pretty heavy stuff, y'know?"

    show reed sad with dissolve
    Re "Got something I need to get off my chest, anyways."

    A "What? Bit busy dealing with being doxxed here!"

    show anon neutral with dissolve
    "Wait{cps=*.1}...{/cps}"

    show anon:
        easein_cubic 1 xcenter 0.75
    with None
    show anon neutral flip with dissolve
    pause .5

    A "Wait, get what off your chest?"

    A "Were{cps=*.1}...{/cps} were you in on it?"

    show fang:
        easein_quart 1 xcenter 0.575
    with None
    show fang angry flip behind anon with Dissolve(.25)
    show reed shocked with dissolve

    "Fang’s questioning glare makes Reed shudder."

    show reed:
        easein_quart 1 xcenter 0.175
    Re "Wait, wait, no, don’t get the wrong idea, man!"

    show fang:
        easein_back 1 xcenter 0.55
    F "Reed{cps=*.1}...{/cps} how did this happen?"

    Re "No no, it went more like{cps=*.1}...{/cps}"

    show reed considering with Dissolve(.25)
    Re "I was getting the projector set up earlier, right?"

    show fang unimpressed flip with Dissolve(.25)

    Re "Something was wrong with the lens, and I didn’t have enough time."

    Re "{cps=*.1}...{/cps}So I asked Trish to go get the thing from Naomi."

    show fang sad flip with Dissolve(.25)

    Re "I guess she must’ve, like{cps=*.1}...{/cps} changed the slides before giving it to me?"

    show anon sad flip with Dissolve(.25)
    A "{cps=*1.4}And you didn’t think to check?!{/cps}"

    show reed sad 
    show fang sad flip
    with dissolve
    "Reed deflates."
    pause .5

    A "{cps=*.1}...{/cps}Damn it, Reed{cps=*.1}...{/cps}"

    Re "Look, man{cps=*.1}...{/cps} Trish isn't a bad person."

    show anon unimpressed flip with Dissolve(.25)
    A "Bitch sure has a funny way of showing it!"

    show reed considering with dissolve
    Re "Dude.{w=.3} I know you're still hurting from what she did but like-"

    A "Yeah, what could have POSSIBLY given that away?!"

    show reed:
        easein_back 0.5 xcenter 0.2
    show reed angry with Dissolve(.25)
    Re "BRO!{w=0.3} Let me finish!"

    show anon neutral flip with dissolve
    "Reed's raised voice takes the wind out of my lungs."

    "That's the first time I think I've ever heard him raise his voice."
    pause .5

    Re "Trish messed up pretty bad, bro. Like massively, hugely messed up."

    Re "Not gonna argue with that. She abused my trust too, dude."

    Re "When she gave me the presentation from Naomi I didn’t think she’d do anything like that."

    Re "But did you ever consider {i}why{/i}?"

    A "{cps=*.1}...{/cps}Because she's a two-bit cunt?"

    show reed considering with dissolve
    "Reed sighs again, with a noticeable lack of smoke surrounding him."

    Re "Dude{cps=*.1}...{/cps} you and Trish have always been at each others' throats."
    
    show reed unimpressed with Dissolve(.25)
    Re "But like, why even?"

    "I open my mouth to answer but can't find the words."

    "Or the reason?"

    show reed angry with dissolve
    Re "Did'ja ever stop to consider WHY Trish always gave you a hard time?"
    pause 0.5
    A "{cps=*.1}...{/cps}Not really{cps=*.1}...{/cps}"

    show reed unimpressed with dissolve
    "Another sigh, this time with an expectant look from Reed."

    Re "Did you ever even try, bro?"

    A "{cps=*.1}...{/cps}"

    A "{cps=*.1}...{/cps}No."

    show reed considering with dissolve
    Re "And that's the problem, dude."

    "Reed has a pained expression on his face, and a quick glance shows Fang’s is even worse."

    Re "Like, I know it sucks. Trish tricked me and all too, and that hurts, y’know?"

    Re "But maybe try and think why Trish did this, alright bro?"
    window hide
    window auto
    pause .5

    menu:
        "Not exactly in the introspective sort of mood right about now.":
            pass

        "I refuse to accept that I had any part to play in this debacle other than being the victim.":
            pass

        "I guess Reed might have a point...":
            pass

    pause .5

    "Trish can still burn in hell for all I care."

    stop music fadeout 3.0
    window hide
    window auto
    pause 1

    Sp "Three MONTHS!"

    Sp "THREE MONTHS from graduation and you PULL A STUNT LIKE THIS?!"
    #play music 'audio/OST/protestra_punk.ogg' fadein 1.0

    show anon neutral 
    show fang considering flip
    with dissolve
    "Spears’ stern voice grilling Trish in his office rips me from my thoughts."

    "Good! She deserves it!"

    Sp "I’ve half a mind to have campus security escort you out of here and send you to Reef City Continuation!"
    window hide
    window auto
    
    show fang:
        easein_back 1 xcenter 0.6
    show reed:
        pause .2
        easein_quart 0.75 xcenter 0.225
    with None
    show anon behind fang
    show fang angry
    show reed angry 
    with dissolve
    pause .5

    "Fang and Reed both hiss at that."

    "What the fuck does that mean?"
    pause .5

    Sp "You have five minutes to explain why I shouldn’t do that right now."

    "I couldn’t hear Trish’s full response through the door but she was obviously crying."

    "After what SHE did?"

    show fang:
        ease_cubic 1 xcenter 0.65
    show anon:
        pause .25
        ease_cubic 1 xcenter 0.8
    with None
    show fang sad 
    show reed considering
    with dissolve

    "Fang leaned in, trying to listen through the door to hear what the bitch was saying."

    "Because of her arms I was pulled closer too."

    "I heard the trollop’s whimpering and wanted nothing more than to really make her cry."
    pause .5

    T "-all HIS fault-"

    "My fault?! I did fucking nothing to that purple pole-smoker."

    T "-didn’t know what else I could do-"

    "Not fucking show half the school the cringiest thing I’ve ever done and commit what amounts to character assassination?!"

    T "-some asshole from the sticks-"

    "I’ll show that cunt some fucking sticks."

    T "-driving Fang away!"
    window hide
    window auto
    pause .5

    "{cps=*.1}...{/cps}What."
    
    "What does Fang have to do with any of this?!"

    "She wasn’t the one bitching about every damn thing I do!"

    show fang very sad with dissolve
    "I glance over to Fang whose expression seems even worse now."

    F "{cps=*.1}...{/cps}"

    "Looking at her this way makes a part of me feel even shittier."

    "Like I did cause this."
    pause .5

    "Fuck Trish though, she’s been an ass to me from the beginning!"
    pause .5

    Sp "Anon! Will you please step into my office!"

    "Spears’ voice shocks me from my eavesdropping."

    "What am I supposed to say to Trish?"

    show fang sad with dissolve
    "Fang tries to give a reassuring smile but it’s so fragile."

    "Like this is all her fault and not that backstabbing bitch."

    "Reed gives a silent nod. No thumbs up this time."
    window hide
    window auto

    show anon:
        easeout_cubic 1 xcenter 1.2
    pause .5
    hide anon with dissolve
    pause .5

    # added music - very long chunk of silence otherwise
    play music 'audio/ost/ballad_of_the_boot.ogg' fadein 4
    scene office spears
    show spears neutral flip:
        yalign 0.1 xcenter 0.8
    show trish sad:
        yalign 0.0 xcenter 0.45
    with Fade(1, 0.5, 1.5)
    pause .5

    "I enter Spears’ office and my eyes are immediately drawn to Trish sitting in front of his desk surrounded by crumpled up tissues."
    window hide
    window auto
    pause .5

    show anon neutral behind trish with dissolve:
        yalign 0.1 xcenter 0.0
        easein_cubic 1 xcenter 0.2
    pause 1

    Sp "Trish, is there anything you would like to tell Anon?"
    pause .5

    "I’ve never seen her like this."
    show dimmer_light behind anon, trish:
        alpha 0
        linear 1 alpha 1
    window hide
    window auto
    
    show trish:
        easeout_cubic 0.5 xcenter 0.475
        easein_back 0.5 xcenter 0.5
    pause .25
    show trish sad flip with dissolve
    pause 1
    
    T "It’s all your fault."

    T "Who are you to come here and take Fang away!"

    T "You’re just some nobody from the middle of nowhere who only cares about yourself!"
    pause .5

    T "I helped pull Fang out of their shell."

    "And made her a social pariah in the process."

    T "My band was doing great before you came here!"

    "I set up the only successful show you ever played."

    show trish fury flip:
        yanchor 0 ypos 0.3
        easein_quart 1 xcenter 0.525
    with Dissolve(.25)
    T "And then you show up and start manipulating everyone!"

    T "Because you’re a selfish control freak!"
    show trish fury point flip with Dissolve(.25)

    T "Everything has to revolve around you!"

    T "Fang and Reed and me were going to make it to the top!"

    T "But you stole everything from me because you didn’t understand us!"
    
    show trish sad flip with Dissolve(1):
        yalign 0.0
        easein_quart 1 xcenter 0.5
    pause .25

    T "No one understands us!"

    "Trish is cut off by a horrid sob, her head falling into her hands and new tears spilling from her eyes."
    window hide
    window auto
    pause .75

    "Raptor Jesus on his cross of rock that’s a lot to unpack."

    "It’s like you didn’t even try to understand me either."
    show dimmer_light:
        linear 0.75 alpha 0
    window hide
    window auto
    pause .5

    Sp "Anon, is there anything you want to add?"

    "Like how she’s not worth the oxygen?"
    pause .5

    "But if this really is all about Fang{cps=*.1}...{/cps}"
    window hide
    window auto
    pause .5

    $ TalkedWithTrish = 0

    menu:

        "Talk with Trish":

            pause .5
            jump .TalkWithTrish

        "Ignore Trish":

            pause .5
            jump .IgnoreTrish


    label .TalkWithTrish:

    $ TalkedWithTrish = 1

    "I turn to the pitiable purple punk-rocker."

    Sp "{cps=*.7}{alpha=0.75}{i}\"You are not the only person in the world.\"{/i}{/alpha}{/cps}"
    pause .5

    "Maybe Reed was onto something."

    "I{cps=*.1}...{/cps} think I finally get it{cps=*.1}...{/cps}"
    pause .5

    A "Look, Trish."
    
    A "Maybe we didn’t start off right. And yeah, I can be an asshole."

    show trish:
        easein_quart 1 xcenter 0.52
    show trish surprised flip with dissolve
    "She looks up at me, surprise written on her teary eyed face."

    A "I didn’t mean to drive you and Fang apart or anything. I just want to be Fang’s friend."

    A "But after what you fucking did. Fucking digging up my past? Airing it to every senior?"

    A "And all for Fang?"
    
    A "She’s outside the door thinking this is all her fault!"
    window hide
    window auto
    pause .5

    show trish:
        easein_quart 1 xcenter 0.53
    show trish sad flip with Dissolve(1)
    pause .25

    "That got a response from Trish."

    "Her head dipped down and her fingers curled into the hem of her hoodie."

    A "Maybe it’s your fault for being such a bitch."

    A "Maybe it’s mine. I don’t know."

    A "But it sure as shit isn’t Fang’s!"

    "Another choked sob racked her body and the tears started anew."
    pause 0.5

    A "{cps=*.1}...{/cps}I’m sorry for being a poor friend to you."
    
    A "But after what you did?{w=.3} I don’t know if I can forgive that."

    show spears happy flip with dissolve
    "Spears nods in approval, a fatherly grin stretching his cheeks."

    Sp "That was well said, son. You’ve come a long way since your first day."

    show spears neutral flip with Dissolve(.25)
    Sp "You can leave. Take the rest of the day if you need it."

    "I rise from my chair and make for the door."

    show anon:
        ease_back 1 xcenter 0.15
    pause .25
    show anon neutral flip with dissolve
    "But I’m stopped by what Trish just muttered."

    stop music fadeout 6
    T "{size=-5}{cps=*.1}...{/cps}{cps=*.6}s’my fault{/cps}{cps=*.1}...{/cps}{/size} {w=0.3}{size=-10}m’sorry.{/size}"

    "{cps=*.1}...{/cps}"

    A "You should tell that to Fang."
    pause .5

    jump .PostSpearsOfficeTrish


    label .IgnoreTrish:

    stop music fadeout 5
    pause .5

    A "No, I’ve got nothing."
    pause .5

    "Spears sighs like he expected me to add something more."

    "What was I supposed to say?"

    "Forgive her and act like nothing happened?"
    pause .5

    Sp "Well, Anon, I can’t really say I blame you after all of that."

    "Trish remains silent, her eyes locked on the floor."

    Sp "You can go home for the day if you need to."
    window hide
    window auto
    pause .5

    show anon:
        ease_back 1 xcenter 0.15
    pause .25
    show anon neutral flip with dissolve


    label .PostSpearsOfficeTrish:
    "Right before I clamp my hand on the doorknob, Spears speaks up."

    Sp "Oh, and Anon.{w=0.3} Don’t think I didn’t notice."

    "Uh oh."

    show anon:
        "anon neutral" with Dissolve(1)
    "I slowly turn back to him."
    window hide
    window auto
    pause .5

    Sp "{cps=*.1}...{/cps}"

    A "{cps=*.1}...{/cps}"

    Sp "Your waifu is trash and your taste is shit."

    Sp "My door is always open so I can share some quality anime."

    pause 0.5
    "What."
    window auto
    window hide
    pause .5

    scene black with Dissolve(1)
    pause .5

    "I open the door to see Fang again, expression complex, leaning against the door’s frame."
    pause .5

    play music 'audio/OST/she_fucks_human_men.ogg' fadein 4
    scene hallway
    show fang sad flip:
        yalign 0.0 xcenter 0.75
    show reed considering flip:
        yalign 0.1 xcenter 0.95
    with Dissolve(1.5)
    pause .5

    "Reed has taken my place beside her with a comforting arm around her shoulder."

    "If this was any other situation I might have felt a bit jealous."
    window hide
    window auto

    show anon neutral flip behind reed, fang:
        yalign 0.1 xcenter 0.9
        easein_cubic 1 xcenter 0.62
    with dissolve
    pause .75

    F "Hey."

    "A heavy sigh escapes my lips."

    show anon:
        ease_cubic 1 xcenter 0.55
    pause .5
    show anon neutral with dissolve
    A "Hey."

    show reed neutral flip with Dissolve(.25)
    Re "Doing okay, bro?"

    A "I’d frankly like to just disappear right now."

    A "{cps=*.1}...{/cps}I think I’ll just go home."

    F "I uh{cps=*.1}...{/cps} can ditch.{w=.3} If you need me to come with."

    "Fang looks at the door to Spear’s room for a bit, then back to me."

    "Trish is probably having to call her parents right now."

    "Fang must've heard everything in the office."

    if TalkedWithTrish == 1:
        
        window hide
        window auto
        pause .5

        menu:

            "Wait for Trish to exit the office":

                pause .5
                jump .WaitForTrishToExit

            "Go Home Early":

                pause .5
                jump .GoHomeEarly

    else:

        jump .GoHomeEarly

    label .WaitForTrishToExit:
    $   anonscore += 1

    #play music 'audio/OST/fighter.ogg' fadein 1.0
    A "You worried about her, too?"

    show fang very sad flip with dissolve
    "Fang turns her head down to her shoes."

    F "{cps=*.1}...{/cps}"

    F "How could I not tell something like this was happening?"

    A "You know it’s not your fault."

    F "Doesn’t mean I don’t feel guilty about it."

    show fang sad flip with dissolve
    "She picks her head up to look me in the eye."

    F "We should leave{cps=*.1}...{/cps} you probably don’t want to see her when she gets out."

    A "Actually, I think we should wait. Looks like you have something to say to her."

    F "Well, yeah, but{cps=*.1}...{/cps}"

    A "There’s something else I wanted to tell her, too."
    window hide
    window auto
    pause .5

    show fang surprised flip with Dissolve(.25)
    F "There is?"

    Re "There is?"

    show fang unimpressed flip with Dissolve(.25)
    F "You sure you should be talking to her when you’re still this upset?"

    show anon shrug with dissolve
    A "It’s nothing bad, promise."
    show anon neutral with dissolve

    show reed explanatory flip with Dissolve(.25)
    Re "It’s a good call, dude."
    show reed neutral flip with Dissolve(.25)
    
    show fang considering flip with Dissolve(.25)
    F "Mmmmm{cps=*.1}...{/cps}"

    A "You can go first."

    stop music fadeout 7
    play ambient 'audio/effects/classroomloop.ogg' fadein 2

    show fang neutral flip with Dissolve(.25)
    "Fang gives a small nod, and the three of us slide down the wall into sitting positions."
    window hide
    window auto
    
    show anon:
        easein_cubic 1 xcenter 0.63
    show anon neutral flip with dissolve
    pause 0.4
    show anon:
        parallel:
            easeout_cubic 0.5 yalign -0.3
            easein_back 0.5 yalign -0.6
        parallel:
            easein_back 1.5 xcenter 0.66
    show reed:
        pause .35
        easeout_cubic 0.5 yalign -0.3
        easein_back 0.5 yalign -0.6
    show fang:
        pause .6
        parallel:
            easeout_cubic 0.5 yalign -0.3
            easein_back 0.5 yalign -0.6
        parallel:
            easein_back 1.5 xcenter .76
    pause 2.5

    "The minutes pass."
    window hide
    window auto
    pause 1

    show fang sad flip with dissolve
    F "What do I even say to her{cps=*.1}...{/cps}?"

    A "{cps=*.1}...{/cps}"

    "I’m not entirely sure either."
    pause .5

    "Reed awkwardly toys with his tail in silence, suddenly a lot less contemplative than before."

    "The clasped hands around my knees start to leave red marks on each other."

    "I can’t find the energy to shift them."
    window hide
    window auto
    pause 1

    "Aeons later, Trish emerges from the office."
    window hide
    window auto
    pause .5

    show trish sad flip behind anon:
        yalign 0.0 xcenter 0.6
    show trish:
        easein_cubic 1.75 xcenter 0.2
    show reed considering flip
    with Dissolve(1)
    pause .5

    "Her tears have become shiny trails reflecting the sterile light of the hallway."

    show fang:
        easein_cubic 1.5 yalign 0.0
    pause .5

    "Hesitantly, Fang gets up to speak with her."

    "That makes one of us."
    window hide
    window auto
    pause .5

    show trish sad with dissolve
    pause 1

    "For a while, the two just stare at each other."
    window hide
    window auto
    pause .5

    "Eventually{cps=*.1}...{/cps}"

    F "{cps=*.1}...{/cps}Why?"

    F "Why the fuck did you do this to Anon?"

    F "Do you actually think I’d be okay with this?"

    F "Anon is just as much my friend as you or Reed!"

    show fang angry flip with Dissolve(.25)
    F "That was something those douchebags who make fun of our band would do."

    T "{cps=*.1}...{/cps}I thought he was a bad influence{cps=*.1}...{/cps}"

    T "{cps=*.1}...{/cps}On you{cps=*.1}...{/cps} {w=0.2}the band{cps=*.1}...{/cps}"

    T "Everything is changing, Fang, and I don’t like it."

    T "All because of Anon."

    show fang:
        ease_cubic 2 xcenter 0.4
    show fang sad flip with dissolve

    F "Then why didn’t you just fucking talk to us?"

    F "Anon isn’t some asshole trying to rip everything apart."

    T "I know what you told me, Fang, but like{cps=*.1}...{/cps}"

    T "But you deserve better, he’s not-"
    
    show fang unimpressed flip with dissolve

    "I catch Trish throwing a glance my way as she cuts herself off."
    pause .5

    T "Look, I’m sorry Fang. I'm just trying to look out for you."

    show fang neutral flip with Dissolve(.25)
    F "Look out for me? I can make my own decisions, Trish."

    show fang considering flip with Dissolve(.25)
    "Fang sighs and rubs her temples."
    pause 0.5

    F "{cps=*.1}...{/cps}I’m taking a break from the band."

    show reed behind trish
    show anon behind trish 
    show fang behind trish
    show dimmer_darker behind trish:
        alpha 0
        linear 1 alpha 1
    window hide
    window auto
    pause .5

    "I watch as Trish’s entire world shatters before her eyes."
    pause .5

    "Reed’s lack of reaction tells me they discussed this while I was in Spears’ office."

    show dimmer_darker:
        linear 0.5 alpha 0

    show trish:
        easein_quart 1 xcenter 0.18
    T "W-{w=.3}what?"

    show fang sad flip with Dissolve(.25)
    F "I need time to think{cps=*.1}...{/cps}"
    
    show trish:
        easein_back 0.5 xcenter 0.2
    T "Fang wait-"

    F "Bye."
    window hide
    window auto

    show fang:
        ease_cubic 1 xcenter 0.5
    pause .25
    show fang very sad with dissolve

    "Fang turns away from Trish and starts walking away."

    F "I’ll wait by the exit while you talk, Anon."
    window hide
    window auto
    show fang:
        easeout_cubic 1 xcenter 0.9
    show fang sad with dissolve
    hide fang with dissolve
    pause .5

    show reed:
        easein_cubic 1.5 yalign 0.1
    show reed neutral flip with dissolve
    "Reed gets up as she passes by and begins to follow, giving me a thumbs up."

    Re "Give you some privacy, amigo."
    window hide
    window auto

    show reed:
        easeout 1 xcenter 1.2
    hide reed with dissolve
    pause 1

    "{cps=*.1}...{/cps}"

    stop ambient fadeout 3
    play music 'audio/OST/beach chill out.ogg' fadein 1.0
    "And now it’s just the two of us."

    show anon:
        easein_cubic 1.5 yalign 0.1
    pause .5
    "I get up from my spot on the floor, pins and needles in my legs making it more difficult."

    T "{cps=*.1}...{/cps}Now what do you want?"

    A "I fucked up too."
    pause .5

    show trish surprised with dissolve

    "That catches her off-guard."
    pause .5

    A "This is my fault too, ya know? I played a stupid game with this instead of manning up and just talking about it."

    "I stone the fuck up and finally admit it. To the world and myself."

    A "I like Fang."
    
    A "I like her and I know that’s what you’re afraid of."

    A "I was never out to break anything up, I just like Fang. I want to help her."

    A "I never wanted to hurt anyone."

    show trish sad with Dissolve(1)

    "Trish’s eyes glaze over and stare at something in the distance, as if all her worst fears came true."

    "I guess in a way they did today."
    pause .5

    A "I’m done, Trish. I’m not going to fight with you over this."

    A "I won’t fuck with you, you won’t fuck with me."
    pause .5

    A "I’m going home."

    show anon:
        ease_cubic 1 xcenter 0.75
    pause .25
    show anon neutral with dissolve

    "I turn away from Trish as she buries her head in her hands again."

    "Part of me wonders if she’ll use that against me, but right now it just feels good to get it out of my system."
    window hide
    window auto

    show anon:
        easeout_cubic 1 xcenter 0.9
    pause .5
    hide anon with dissolve
    pause 1

    scene hallway mirrored
    show reed neutral flip:
        yalign 0.1 xcenter 0.7
    with Fade(1, 0, 1)

    show anon neutral with dissolve:
        yalign 0.1 xcenter 0.0
        easein_cubic 1 xcenter 0.3


    "As I begin looking for Fang, Reed stops me in the hallway."

    show reed explanatory flip with Dissolve(.25)
    Re "Made the right call talking it out, trust me dude."
    show reed neutral flip with Dissolve(.25)

    "Reed shuffles his feet a bit and scratches his neck."

    show reed considering flip with Dissolve(.25)
    Re "Gonna give you a bit of space after dealing with that. Time to think things over, y’know?"

    show reed:
        ease_cubic 1 xcenter 0.6
    "Suddenly he leans in and lowers his voice."

    show reed neutral flip with dissolve
    Re "You should tell them, bro."

    show reed:
        easeout_cubic 1 xcenter 0.2
    pause .5
    hide reed with dissolve

    "With a cryptic wink he rushes off towards Trish, probably to give her the same kind of therapy."

    show anon:
        ease_cubic 1 xcenter 0.4
    pause .25
    show anon neutral flip with dissolve

    "I throw a quick glance back to see him pull in Trish for a hug. His turn to deal with her now."
    pause 0.5

    "What did he mean by 'tell them'? Tell them wha-"

    stop music fadeout 6

    "{cps=*.1}...{/cps}"

    "Does Reed{cps=*.1}...{/cps}?"

    "How did he{cps=*.1}...{/cps}?"

    "{cps=*.1}...{/cps}"
    pause .5

    "So much for privacy."
    pause .5

    "I shake the thoughts from my mind and head in the direction Fang went."

    "That can wait."
    window hide
    window auto
    show anon:
        easeout_cubic 1.5 xcenter 0.8
    pause .5
    show anon neutral with dissolve
    hide anon with dissolve
    pause .5

    scene black with Dissolve(1)
    pause .5

    "I catch up to Fang near the front of the school as I mentally prepare myself for what’s coming."
    pause .5

    jump .WalkOfShame


    label .GoHomeEarly:

    stop music fadeout 5

    A "Sure, let’s get out of here."

    show reed considering flip with dissolve
    "Reed lets out another heavy sigh."

    Re "Gonna stick around. Try and talk with Trish n’all."
    window hide
    window auto
    pause .5

    show fang:
        ease_cubic 1 xcenter 0.675
    show fang sad behind anon with dissolve
    pause 1

    show fang very sad with dissolve

    F "Reed, I{cps=*.1}...{/cps} I’m taking a break from the band."

    show reed shocked flip with Dissolve(.25)
    "Reed’s expression shifts to one of sadness and shock."

    show fang sad with dissolve
    F "I just{cps=*.1}...{/cps} need time to think, alright?"

    show reed sad flip with dissolve
    Re "Like, y’know that’ll crush Trish{cps=*.1}...{/cps}"

    show reed considering flip with dissolve
    Re "But can’t really stop you if you think it’s right, dude. Taking a breather and all{cps=*.1}...{/cps}"

    F "Thanks, Reed."

    show reed neutral flip with dissolve
    "Reed offers a weak smile as we turn away from the principal’s office."
    window hide
    window auto

    show anon:
        ease_cubic 1 xcenter 0.425
    show fang:
        ease_cubic 1 xcenter 0.55
    with None
    show anon neutral flip behind fang
    show fang sad flip
    with dissolve

    show reed explanatory flip with Dissolve(.25)
    Re "See ya, space cowboy."
    show reed neutral flip with Dissolve(.25)
    pause .25

    "Wait,{w=0.3} did he just{cps=*.1}..?{/cps}"
    pause 0.5

    "God damn it, Reed."
    window hide
    window auto

    show anon:
        easeout_cubic 1 xcenter 0.1
    show fang:
        easeout_cubic 1 xcenter 0.225
    pause .5
    hide anon
    hide fang
    with dissolve
    pause .5

    scene black with Dissolve(1)
    pause .5

    "We make our way to the front of the school as I mentally prepare myself for what’s coming."
    pause .5

    label .WalkOfShame:

    play music 'audio/OST/you can_t sage here.ogg' fadein 1.0
    "Time for the Walk of Shame."
    pause .5

    "As I make my way through the hall I do my best to ignore the passing jeers from teens I don’t even know."

    "I guess it’s already spread to the lower years too."

    "Fucking lightspeed capable rumor mill."

    unknown "HEY DO THE NARUTO RUN."

    unknown "Look at the pathetic weeb."

    unknown "How’s your 2D girlfriend Anon?"

    unknown "Hey Anon, need to borrow a jar?"

    St "Your waifu is great and I love her!"

    A "Not helping, Stella."

    "I keep my head down, avoiding the looks from them all."

    "Shouldering open the door I’m blinded by the morning sun’s glare."
    pause .5

    scene outside school
    show anon neutral at aleft
    show fang sad flip at scenter behind anon:
        xalign 1.1
    with Fade(1, 0.5, 1.5, color="#fff")
    pause .5

    "Within an hour I’ve fallen back to square one."

    "Is it too late to transfer to another school?"
    pause .5

    "Fang steps to the stairs, phone in hand."

    F "I can call us a taxi or something, Anon."

    "I nod at that, moving for the stairs."

    stop music fadeout 3
    unknown "HEY LOSER, THINK FAST!"

    show anon neutral flip at aleft with dissolve
    "I turn towards the voice, and the world slows down."


    show anon fear flip at aleft
    show fang surprised flip behind anon
    with dissolve
    "My field of vision is filled with a soda can, and I freeze up like a deer in headlights."
    window hide
    window auto

    play ambient 'audio/effects/hungrybeast.ogg' fadein 1 volume 0.3

    show sodacan blurred:
        yalign -0.2
        xalign -0.1
        zoom 0.25
        easeout_cubic 0.3 xalign 0.15 yalign 0.12 rotate 60
    play sound 'audio/effects/whoosh.ogg'
    show dimmer_darker behind anon, sodacan with Dissolve(.25)

    menu:
        "Duck.":
            pass
            
        "Dodge.":
            pass

        "Catch it out of the air.":
            pass
    
    pause .5
    "The can smacks me in the forehead while I was mid-stride, and I shift my footing to try and regain balance."
    window hide Dissolve(0.0001)
    window auto

    stop ambient fadeout 1
    show dimmer_darker:
        linear 0.5 alpha 0

    show sodacan blurred:
        linear 0.15 xalign 0.22 yalign 0.22 rotate 90
    play sound "audio/effects/anonDink.ogg" volume 0.5

    pause 0.1
    show anon:
        easein_cubic 1 xalign 0.2

    show sodacan blurred:
        xalign 0.22 yalign 0.22
        linear 0.4 align (.05, 1.5) knot (0, 0.25) rotate -270

    hide sodacan blurred with dissolve
    #show sodacan blurred:
    #  ease_cubic 0.1 xalign 0.3 yalign 0.22 rotate 90
    #  ease_cubic 0.5 xalign 0.5 yalign 1.7 rotate 60

    pause .2
    play ambient 'audio/effects/hungrybeast.ogg' fadein 0.69 volume 0.3
    
    show dimmer_darker:
        linear 0.5 alpha 1
    "Except my foot catches on the edge of the stairlip and slips."

    show fang surprised flip behind anon #Fucking thing keeps wanting to be infront of anon
    window hide
    window auto

    hide dimmer_darker with Dissolve(.25)
    stop ambient fadeout 1
    show anon shocked flip with Dissolve(.1):
        xpos 0.0
        yanchor 0.2
        easeout_quad .6 rotate 90 yalign -0.15 xpos 0.4
    play sound 'audio/effects/anonStairFall.ogg'
    show fang shocked flip behind anon with Dissolve(.25)
    pause 0.1
    scene black

    #show anon with easeinleft:
    #  parallel:
    #    ease_cubic 1.0 rotate 90
    #  parallel:
    #    ease_cubic 0.1 yalign 0.0
    #    ease_cubic 0.3 yalign -0.1
    #    ease_cubic 0.3 yalign -0.2
    #    ease_cubic 0.3 yalign -0.2

    pause 5.5


    #scene outside school with vpunch
    #pause 0.5
    #scene outside school with hpunch
    #play sound 'audio/effects/anonDumbassFall.ogg' fadeout 0.5
    #pause 0.5
    #scene outside school with vpunch
    #pause 0.5
    #scene outside school with hpunch
    #play sound 'audio/effects/anonHeadbutt.ogg' fadeout 0.5
    #scene imfreeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeefaaaaaaallllllliiiiiiiiiiiinnnnnnnnnnnnnnnnnnnnnnnnnnnn
    #scene black with fade
    "{cps=*.05}...{/cps}"

    A "{cps=*.2}Uuurg.{/cps}"

    unknown "Oh fuck, we need to split before the Caveman gets here!"

    F "ANON!"

    "My lungs feel like they’re on fire."

    "I think my feet touched the back of my head."
    pause .5

    "I peel myself from around the bollard, feeling every bone in my body creak painfully."
    window hide
    window auto
    pause .5

    play ambient 'audio/effects/outdoorLoop.ogg' fadein 2
    scene schooloutside_blur #at wiggle
    #scene outside school
    show anon sad flip:
        xcenter 0.8 yalign -0.4 rotate 80
        ease_cubic 2.0 rotate 0
    with Dissolve(1.5)
    pause 1

    A "Argh{cps=*.1}...{/cps}{w=0.3} fuck."

    show fang shocked:
        yalign 0.0 xcenter 0.3
        easein_cubic 1 xcenter 0.45
    with dissolve
    F "Holy shit! You’re alive!"

    A "Am I? Ow."

    show anon:
        ease_cubic 1.5 yalign 0.3 # wtf why is yalign 0.1 lower than it should be
    pause .5

    "Nothing seems to be broken{cps=*.1}...{/cps}{w=0.3} I’ve been in worse."

    "Honestly my ego’s more injured than I am."

    show fang sad with dissolve
    F "Can you walk?"

    A "Yeah, sure, sure."

    show anon shrug flip with dissolve
    A "This’s nothing compared to field day back at my old school."

    show anon:
        easein_back 1 xcenter 0.775
    "I try taking a step and my knee involuntarily twists in a direction it’s not supposed to."
    window hide
    window auto

    show anon fear flip 
    show fang surprised
    with Dissolve(.25)
    show anon:
        easeout_cubic 0.5 yalign -0.5 alpha 0
    stop music fadeout 5
    scene black with dissolve
    play sound 'audio/effects/anonTheaterFall.ogg' volume 0.5
    pause .5

    "Suddenly, I’m doing the Seth McFarlane pose again."
    #Have you ever tried not being ironic for once in your life

    F "Oh no. Ohhh no. Let me help you up."
    window hide
    window auto
    pause .5

    stop ambient fadeout 5
    play music 'audio/OST/west_coast_kicking.ogg' fadein 3
    show schooloutside blurred
    show fangcarriesanon
    with Dissolve(2)
    pause .5

    "She tucks her arms around my shoulder and pulls me to my feet again."

    F "Let’s just get to the bench over there."

    F "The taxi will be here in like five minutes."

    "Using Fang as a second foot, I eventually make it to the bench."

    "I still can’t bend either leg, so I just sort of splay against the sidewalk."

    "Fang sits on the other end and starts digging through her pockets."

    F "Uhh{cps=*.1}...{/cps} I think I heard somewhere that nicotine relieves a bit of pain{cps=*.1}...{/cps}"

    A "Yeah{cps=*.1}...{/cps} I could use a smoke{cps=*.1}...{/cps} right about now."

    "Fang retrieves one of the cigarettes from the crumpled pack and sparks it to life with her pink lighter."

    "She takes the first draw, then hands it to me."

    "I inhale slowly, my chest aching as my lungs fill with wonderfully numbing nicotine."

    "The minty taste and the cool sensation settling over my skin does help to relax my painfully tense muscles."

    "Before I know it the cigarette in my fingers is nothing but a smoldering filter."
    pause .5

    F "Looks like our ride’s here."

    "A grimy beater of a taxi pulls up to the curb, driven by an equally grimy velociraptor."

    "Clearly one of the three left operating in the city."
    pause .5

    "Fang helps me to my feet and over to the cab, opening the door so I can shamble in."
    window hide
    window auto
    pause .5

    scene taxi day with Dissolve(1)
    pause .5

    D "{cps=*.1}...{/cps}Shit, kid, you look like you got into a fight with a steamroller and lost."

    A "Mmm."

    D "Now where’re you kids heading on a school day? Maybe the hospital?"

    A "Home."

    D "Sure thing kid. Got the address?"

    A "{cps=*.1}...{/cps}Two-thirty-seven South St. Hammond street."

    "The driver sucks in a breath through his teeth."
    pause .5

    D "Skin Row, eh?{w=0.3} Well I can take you s’far as the edge of the neighborhood, deal?"

    A "Yeah, whatever. Just take me home{cps=*.1}...{/cps}"

    "The cab speeds off away from the school."
    window hide
    window auto
    pause 1

    F "{cps=*.1}...{/cps}I still can’t believe that Trish would do something like that."

    "The cab driver lets out a laugh."

    D "You got your ass handed to you by a girl, didn’t you?"

    "I don’t bother responding while Fang kicks the back of his seat."

    D "Yeah, yeah, I didn’t want a tip much anyways{cps=*.1}...{/cps}"
    pause .5

    F "Why doesn’t the driver want to drive all the way to your place?"

    F "It can’t be that bad, right?"

    A "Uhhh{cps=*.1}...{/cps} that reminds me."

    A "Hold this{cps=*.1}...{/cps} for me."

    "I toss my pocket knife into Fang’s lap, she looks at me with a nervous smile like she expects a punchline."

    F "{cps=*.1}...{/cps}"

    F "{cps=*.1}...{/cps}Oh."

    A "Joking{cps=*.1}...{/cps} kinda{cps=*.1}...{/cps}"

    A "Haven’t needed to shiv someone yet{cps=*.1}...{/cps}"
    pause .5

    "Talking hurts, breathing too."

    "Each breath I take feels like my ribs are gonna shatter."

    stop music fadeout 6

    "Fang must have noticed since she kept silent after that."
    window hide
    window auto
    pause .5

    D "Alrighty, end of the line."
    
    D "That’ll be fifteen bucks even."

    A "There’s still a few blocks we gotta walk."
    pause .5

    scene black with Dissolve(1)
    pause .5

    "I manage to limp out of the car and Fang drops a few crumpled bills in her seat and slams the door behind her."

    "The car peels out and disappears around the corner."
    pause .5

    A "Well, {w=0.2}no place to go but home."
    pause .5

    play music 'audio/OST/Skinrow Soul.ogg' fadein 3
    scene skinrow with Dissolve(2)
    pause .5

    F "Wait, you still can’t walk, right?"

    "I can probably make it a good fifty yards."

    F "Hang on, give me your shoulder."

    A "No, don’t worry abou-"

    "Ignoring my protests, Fang wraps my arm around her back for support."

    F "Where are we going?"

    A "Uhh{cps=*.1}...{/cps} first turn is a right up here{cps=*.1}...{/cps}"
    pause .5

    "Wait{cps=*.1}...{/cps} Fang is coming over to my place?"

    "Fang is coming over to {i}my{/i} place?"

    "Fang is coming over to my {i}place{/i}?"
    pause 0.5

    "I don’t want her to see how I live!"
    
    stop music fadeout 5
    "{cps=*.1}...{/cps}"
    pause .5
    
    "Crap, did I leave Saturnia on?"

    "{cps=*.1}...{/cps}"
    pause .5

    return