406 lines
9.5 KiB
Plaintext
406 lines
9.5 KiB
Plaintext
# The Mous Pad
|
||
|
||
label chapter_x2:
|
||
|
||
stop music fadeout(3)
|
||
scene black with Dissolve(2)
|
||
pause 1
|
||
|
||
scene skinrow
|
||
show anon neutral flip:
|
||
yalign 0.1 xalign 0.7
|
||
show black
|
||
show viewfinder
|
||
show rec:
|
||
ypos 0.072 xpos 0.91
|
||
block:
|
||
alpha 1
|
||
pause .5
|
||
alpha 0
|
||
pause .5
|
||
repeat
|
||
with Dissolve(1)
|
||
pause 2
|
||
|
||
A "Right, you’re recording?"
|
||
window hide
|
||
window auto
|
||
pause .5
|
||
|
||
# appreciating the moment
|
||
# appreciating the scenery
|
||
# fuck you I like this chick
|
||
play music 'audio/ost/fuck you i like this chick.ogg' fadein 0.5
|
||
hide black with Dissolve(1)
|
||
pause .5
|
||
|
||
show anon happy flip with dissolve
|
||
A "Heyyy, what’s up? It’s ya boy, Anon, and this is my criiiiiiiiiiiib!"
|
||
pause .5
|
||
|
||
F "Dork{cps=*.1}...{/cps}"
|
||
|
||
show anon neutral flip with Dissolve(.25)
|
||
A "Quiet you!"
|
||
|
||
A "Ignore the hired help."
|
||
pause .5
|
||
|
||
F "Hired?!"
|
||
|
||
A "Shush!"
|
||
|
||
show anon:
|
||
easein_cubic 1.5 xalign 0.8
|
||
show anon shrug flip with dissolve
|
||
A "We’re right in the heart of Skin Row, one of Volcaldera Bluff’s most historic cultural districts!"
|
||
pause .5
|
||
|
||
F "Yeah, if you call crack ‘cultural’{cps=*.1}...{/cps}"
|
||
|
||
A "{cps=*.1}...{/cps}CULTURAL districts!"
|
||
pause .5
|
||
|
||
A "I’ve been living here for almost seven months and I wouldn’t trade it for anywhere else in the state."
|
||
|
||
show anon neutral flip with dissolve
|
||
A "So let’s head on inside for the grand tour!"
|
||
window hide
|
||
window auto
|
||
pause .5
|
||
|
||
scene room anon day alt
|
||
show viewfinder
|
||
show rec:
|
||
ypos 0.072 xpos 0.91
|
||
block:
|
||
alpha 1
|
||
pause .5
|
||
alpha 0
|
||
pause .5
|
||
repeat
|
||
with Fade(1, 0, 1)
|
||
pause .5
|
||
|
||
F "What’s so ‘grand’ about a one-room apartment? My bedroom is bigger than this!"
|
||
|
||
A "Fang I swear to god, don’t make me ask Reed to do this instead."
|
||
pause .5
|
||
|
||
A "So this is the kitchen area, loaded with all the essentials I need to get me through the week. Alfredo, carbonara, pesto, you name it and I can cook it."
|
||
|
||
F "Carbonara is pretty good, I’ll give you that{cps=*.1}...{/cps}"
|
||
|
||
A "Moving on- Fang! You don’t need to show the refrigerator!"
|
||
|
||
F "You call thirty energy drinks ‘essential’?"
|
||
|
||
A "You try getting through a 48 hour Rock Ring 2 marathon without those!"
|
||
pause .5
|
||
|
||
A "Anyways, make sure you get a good pan view of the apartment."
|
||
window hide
|
||
window auto
|
||
pause .5
|
||
|
||
show anon shrug behind viewfinder:
|
||
yalign 0.1 xalign -0.4
|
||
show anon:
|
||
easein_cubic 1 xalign 0.1
|
||
with dissolve
|
||
pause .5
|
||
|
||
"This is what I call the ‘Mous Pad’."
|
||
pause .5
|
||
|
||
F "You have literally never called it that before."
|
||
|
||
F "Wait. Why are you doing this again?"
|
||
|
||
show anon neutral flip with dissolve
|
||
A "My forum pen-pal dared me to do it."
|
||
pause .5
|
||
|
||
F "Your{cps=*.1}...{/cps} pen-pal? You’re trying to impress some weirdo on the Internet with{cps=*.1}...{/cps} this."
|
||
|
||
A "Yeah, her screen name’s StegoStar231. I’m pretty sure she’s from Japan. Cool, huh?"
|
||
|
||
F "‘Her’? You’re sure you aren’t just being groomed?"
|
||
|
||
A "No, shut up."
|
||
|
||
show anon:
|
||
easein_cubic 1 xalign 0.4
|
||
pause .25
|
||
show anon neutral with dissolve
|
||
|
||
A "Anyways, next is the battlestation, ready for all those late-night raid sessions with the clan."
|
||
|
||
show anon:
|
||
easein_back 1 xalign 0.0
|
||
|
||
A "And THIS little guy is Metal Gear RAYmba! Custom modified with a railgun for stealth launches at the science teacher!"
|
||
|
||
F "Some weirdo forced him to buy a phone roomba on our first date and he decided to keep it."
|
||
|
||
A "And it was the best decision I made that day!"
|
||
pause .5
|
||
|
||
show anon neutral flip with dissolve
|
||
A "{cps=*.1}...{/cps}Why are you giving me that look? Moving on!"
|
||
|
||
show anon:
|
||
easein_cubic 1.5 xalign 0.3
|
||
A "The bed. Where I do all my sleeping."
|
||
|
||
pause .5
|
||
F "Among other things."
|
||
|
||
A "Fang! How vulgar!"
|
||
window hide
|
||
window auto
|
||
pause .5
|
||
|
||
show anon:
|
||
ease_cubic 1 xalign 0.9
|
||
pause .25
|
||
show anon neutral with dissolve
|
||
pause .25
|
||
|
||
A "My TV, XROX hooked up and ready to play Rock Ring at a moment’s notice."
|
||
|
||
A "And my closet, with all the clothes I’ll ever need."
|
||
pause .5
|
||
|
||
F "What the fuck? I thought you just kept cleaning the same shirt over and over. Why do you have so many?"
|
||
|
||
show anon neutral flip with dissolve
|
||
A "Am I giving a tour to StegoStar or you?"
|
||
|
||
F "Tell me more about this ‘StegoStar’ character. What’s ‘her’ deal?"
|
||
|
||
A "Dunno what there is to say. She likes anime and- wait, you aren’t jealous, are you?"
|
||
|
||
F "I’d be jealous if it was an actual girl you were talking to, you dweeb."
|
||
|
||
A "Good. Between you and me, she’s not really my type."
|
||
pause .5
|
||
|
||
F "And you’re taken."
|
||
|
||
A "And I’m happily taken."
|
||
pause .5
|
||
|
||
show anon happy flip with dissolve
|
||
A "Anyways, uh, I think that’s about it for my crib tour. Hope you enjoyed, StegoStar. Make sure you get back to me about the new Lucky Star episode, too."
|
||
|
||
show anon neutral flip with dissolve
|
||
A "And done."
|
||
window hide
|
||
window auto
|
||
pause .5
|
||
|
||
hide rec
|
||
hide viewfinder
|
||
with Dissolve(.25)
|
||
pause .75
|
||
|
||
show fang neutral:
|
||
yalign 0.0 xalign -0.4
|
||
show fang:
|
||
easein_cubic 1 xalign 0.1
|
||
with dissolve
|
||
pause .5
|
||
|
||
F "So, does StegoStar have any other hobbies?"
|
||
|
||
A "I, err, think she’s into card games?"
|
||
|
||
show fang considering with Dissolve(.25)
|
||
F "Hmmmm{cps=*.1}...{/cps} Card games, huh? Anything else you know of?"
|
||
|
||
A "For not being jealous you sure care a lot about what she does. She sent me some pictures of her garden once."
|
||
|
||
show fang unimpressed with Dissolve(.25)
|
||
F "What, like a zen garden? Or is that some kind of euphemism?"
|
||
|
||
A "What? No! Just flowers and stuff. I can show you if you want."
|
||
|
||
show anon:
|
||
ease_cubic 1 xalign 0.7
|
||
pause 1
|
||
|
||
F "{cps=*.1}...{/cps}"
|
||
pause .5
|
||
|
||
stop music fadeout 3
|
||
show fang:
|
||
easein_quart 1 xalign 0.05
|
||
show fang surprised with Dissolve(.25)
|
||
F "This is Stella’s garden."
|
||
pause .5
|
||
|
||
A "Whaaaat, no it isn’t. See?"
|
||
|
||
show fang neutral with Dissolve(.25)
|
||
F "Anon, this is Stella’s yard."
|
||
pause .5
|
||
|
||
A "Nah, you’re just jea-"
|
||
|
||
show fang:
|
||
easein_back 1 xalign 0.2
|
||
show fang happy with Dissolve(.25)
|
||
F "Here’s her fucking instaglyph, you idiot."
|
||
pause .5
|
||
|
||
show anon:
|
||
easein_cubic 1 xalign 0.8
|
||
A "{cps=*.1}...{/cps}"
|
||
|
||
A "{cps=*.1}...{/cps}"
|
||
pause .5
|
||
|
||
play music 'audio/ost/bayside bumming it.ogg'
|
||
show anon unimpressed flip with dissolve
|
||
A "One moment, I need to use the bathroom."
|
||
window hide
|
||
window auto
|
||
pause .5
|
||
|
||
show fang behind anon
|
||
show anon:
|
||
easeout_cubic 1 xalign -0.2
|
||
pause .5
|
||
hide anon with dissolve
|
||
|
||
play sound 'audio/effects/doorslam.ogg'
|
||
pause .1
|
||
window show Dissolve(0.0001)
|
||
"{b}*SLAM*{/b}" with vpunch
|
||
window hide
|
||
window auto
|
||
|
||
show fang happy flip with dissolve
|
||
pause .5
|
||
show viewfinder
|
||
show rec:
|
||
ypos 0.072 xpos 0.91
|
||
block:
|
||
alpha 1
|
||
pause .5
|
||
alpha 0
|
||
pause .5
|
||
repeat
|
||
with dissolve
|
||
pause .5
|
||
|
||
"*Ring ring ring click*"
|
||
pause .5
|
||
|
||
A "Sooo{cps=*.1}...{/cps} When were you going to tell me?"
|
||
|
||
"{cps=*.1}...{/cps}"
|
||
|
||
A "YOU FUCKING KNOW WHAT!"
|
||
|
||
"{cps=*.1}...{/cps}"
|
||
|
||
A "OH, YOU FUCKING KNOW, STELLA!"
|
||
|
||
show fang:
|
||
easein_cubic 1.5 xalign 0.5
|
||
F "PFFFFFFT."
|
||
|
||
A "OR SHOULD I SAY, STEGOSTAR231!"
|
||
|
||
"{cps=*.1}........{/cps}"
|
||
|
||
A "I THOUGHT I WAS TALKING TO AN ACTUAL JAPANESE GIRL!"
|
||
|
||
"{cps=*.1}...{/cps}"
|
||
|
||
A "NO!"
|
||
|
||
A "A PACHY UNCLE DOES NOT FUCKING COUNT!"
|
||
|
||
show fang:
|
||
easein_elastic 1.5 xalign 0.8
|
||
F "AHAHAHAHAHAHAHAHAHA."
|
||
|
||
A "FANG SO HELP ME-"
|
||
|
||
F "YOU HAD A FUCKING NETCRUSH ON STELLA! AHAHAHAHAHAHAHAHAHA!"
|
||
|
||
"{cps=*.1}.......{/cps}"
|
||
|
||
A "OH SHUT UP THAT WAS TWO YEARS AGO!"
|
||
|
||
F "{cps=*.4}d’aaaaaawww{/cps}. Anon had a {cps=*.5}{i}cruuuush{/i}{/cps}."
|
||
|
||
A "And I HAVE a girlfriend!"
|
||
|
||
"{cps=*.1}.....{/cps}"
|
||
|
||
A "No I will NOT be keeping that promise!"
|
||
|
||
"{cps=*.1}.........{/cps}"
|
||
|
||
A "Apology not accepted!"
|
||
|
||
A "Oh and by the way your husbando is shit!"
|
||
pause .5
|
||
|
||
"*click*"
|
||
|
||
play sound 'audio/effects/doorslam.ogg'
|
||
"*woosh {nw}"
|
||
extend "{b}SLAM{/b}*" with vpunch
|
||
window hide
|
||
window auto
|
||
pause .5
|
||
|
||
show anon sad behind viewfinder:
|
||
yalign 0.1 xalign -0.5
|
||
show anon:
|
||
easein_cubic 1 xalign 0.0
|
||
with dissolve
|
||
pause 1
|
||
|
||
A "Ugh{cps=*.1}...{/cps} I need a smo-"
|
||
|
||
show anon neutral with Dissolve(.25)
|
||
A "Wait."
|
||
pause .5
|
||
|
||
show anon unimpressed with dissolve
|
||
A "Are you still filming?!"
|
||
|
||
show viewfinder:
|
||
linear 0.5 alpha 0
|
||
show rec:
|
||
linear 0.5 alpha 0
|
||
show fang:
|
||
easein_back 0.75 xalign 1.0
|
||
easeout_cubic 1 xalign 2.8
|
||
F "{cps=*.75}AHAHAHAHAHAHAHAHA{/cps}{w=1}{nw}"
|
||
|
||
show anon:
|
||
easein_cubic 1 xalign 0.4
|
||
show anon pissed with Dissolve(.25)
|
||
A "Fang I swear to fu- Get back here!"
|
||
window hide
|
||
window auto
|
||
|
||
show anon:
|
||
easeout_cubic 1 xalign 1.5
|
||
pause .5
|
||
hide anon with dissolve
|
||
|
||
stop music fadeout 4
|
||
pause 2
|
||
|
||
scene black with Dissolve(1.5)
|
||
pause 2
|
||
|
||
return |