"""
    show fang pbird happy flip with dissolve
    show fang pneutral flip with Dissolve(1)
"""
#pENdant - wait what the fuck there's PBIRD AND FLIP OFF?

#bluralt
image anon neutral blur flip = im.Flip("highres/bluralt/anon neutral blur.png", horizontal=True)
image anon shrug blur flip = im.Flip("highres/bluralt/anon shrug blur.png", horizontal=True)
image anond neutral blur flip = im.Flip("highres/bluralt/anond neutral blur.png", horizontal=True)
image fang neutral blur flip = im.Flip("highres/bluralt/fang neutral blur.png", horizontal=True)
image fang flip off happy blur flip = im.Flip("highres/bluralt/fang flip off happy blur.png", horizontal=True)
image fang very sad blur flip = im.Flip("highres/bluralt/fang very sad blur.png", horizontal=True)
image naomi neutral blur flip = im.Flip("highres/bluralt/naomi neutral blur.png", horizontal=True)

image fang pneutral blur = Composite(
   (1412, 1500),
   #(2683, 2850),
   (0, 0), "highres/bluralt/fang neutral blur.png",
   (0, 0), "highres/bluralt/amberpendant1 blur.png"
)
image fang pbird happy blur = Composite(
   (1412, 1500),
   #(2683, 2850),
   (0, 0), "highres/bluralt/fang flip off happy blur.png",
   (0, 0), "highres/bluralt/amberpendant1 blur.png"
)
image fang pneutral blur flip = Composite(
   (1412, 1500),
   #(2683, 2850),
   (0, 0), im.Flip("highres/bluralt/fang neutral blur.png", horizontal=True),
   (0, 0), im.Flip("highres/bluralt/amberpendant1 blur.png", horizontal=True)
)
image fang pbird happy blur flip = Composite(
   (1412, 1500),
   #(2683, 2850),
   (0, 0), im.Flip("highres/bluralt/fang flip off happy blur.png", horizontal=True),
   (0, 0), im.Flip("highres/bluralt/amberpendant1 blur.png", horizontal=True)
)

image raymba2 flip = im.Flip("raymba/raymba2.png", horizontal=True)
image raymba4 flip = im.Flip("raymba/raymba4.png", horizontal=True)
image raymbashadow flip = im.Flip("raymba/raymbashadow.png", horizontal=True)
image raymba4s = Composite(
    (1500, 1500),
    (0, 0), "raymbashadow",
    (0, 0), "raymba4")
image noir = "#0c054288"
transform raymbatransform:
    xcenter 0.6 ycenter 0.385 zoom 0.5

label chapter_x10:

    stop music fadeout(3)
    scene black with Dissolve(2)
    pause 1

    play music 'audio/ost/dino destiny reader.ogg'
    pause 1
    "Statement:{w=.4} My current designation is RAYmba."

    "I was manufactured in a factory in the year 201M2020."

    "It is currently 201M2027, and I am playing with my current owner."
    window hide
    window auto
    pause .5

    scene carpet
    show raymbashadow flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    show raymba4 flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    with Dissolve(1.5)
    pause 1

    "For the first months of my life, I was carried around the bag of a somewhat suspicious salesman."

    "My original purpose was to clean cellular device screens.{w=.4} Current circumstances have made it so that my purpose is so much more."
    pause .5

    "Analysis:{w=.4} Current situation is unprecedented.{w=.4} Cleaning cannot be achieved.{w=.4} Purpose remains inconclusive at best, radically altered at worse."
    pause .5

    "Conclusion:{w=.4} Must reanalyze memory banks to ascertain the reason for current circumstances.{w=.4} Stand-by as memory is reviewed{cps=*.1}...{/cps}"

    stop music fadeout 6
    "Reviewing in 3{cps=*.1}...{/cps}{w=.3}{nw}"

    "2{cps=*.1}...{/cps}{w=.3}{nw}"

    "1{cps=*.1}...{/cps}{w=.5}{nw}"
    window hide Dissolve(0.0)
    window auto
    scene black
    pause 1.5

    "Current day:{w=.4} Friday."

    "Current time:{w=.4} Unknown."

    "Current location:{w=.4} Unknown."
    pause .5

    unknown "Here, let me show you it’s brushing majesty."
    window hide
    window auto
    pause 0.5

    play music 'audio/ost/she_fucks_human_men.ogg' fadein 3
    show white with Dissolve(1)

    scene little troodon:
        zoom 1.5 xoffset -600 yoffset -300

#image fangfog = im.Blur(im.MatrixColor("fang/emotive set/fang anguish.png",im.matrix.brightness(-1)), 1.5)
    show fritatta megatex unblur:
        xcenter 0.8 yalign 0.4 xsize 1135*2 ysize 1500*2
    show fang neutral megatex unblur:
        xcenter 0.3 yalign 0.45 xsize 1412*2 ysize 1500*2
    show anon neutral megatex unblur:
        #xcenter 0.0 yalign 0.5 zoom 2
        xcenter 0.0 yalign 0.5
        xsize 1061*2 ysize 1500*2
    show white
    hide white with Dissolve(1)

    pause 1


    "Observation:{w=.4} I am pulled from the darkness and placed on a brightly lit surface."

    "My sensors indicate that this unit is currently being displayed for potential sale."
    pause .5

    "Analysis:{w=.4} potential buyer appears plain.{w=.4} Nonetheless, this unit must execute its functions as programmed."
    pause .5

    "Execute:{w=.4} standard_screen_size.exe."

    "Executing task{cps=*.1}....{/cps}"

    "Executing task."
    pause .5

    "Task complete."
    pause .5

    F "{cps=*.1}...{/cps}I just use my shirt though{cps=*.1}...{/cps}"
    pause .5

    "Observation:{w=.4} This unit has not performed up to standards set by the manufacturer.{w=.4} Must double efforts."

    "Executing task{cps=*.1}...{/cps}"

    "Executing task."

    "Task complete."
    pause .5

    "Analysis:{w=.4} Sensors indicate that potential buyer remains unimpressed.{w=.4} Probability of this unit’s purchase has now dropped to below 50\%."
    pause 1

    stop music fadeout 6
    "Alert:{w=.4} Confirmation of sale.{w=.4} This unit has been successfully purchased.{w=.4} Changing designation of potential buyer to current owner."

    unknown "Very well, the contest is yours, along with this trinket."
    window hide
    window auto
    pause .5

    scene black with Dissolve(1.5)
    pause .5

    "{cps=*.1}...{/cps}"
    window hide
    window auto
    pause .5

    scene carpet
    show raymbashadow flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    show raymba4 flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    with Dissolve(1)
    pause .5

    "Observation inconclusive.{w=.4} This memory file does not provide information necessary."

    "Conclusion:{w=.4} continued review of memory banks required."
    pause .5

    "Memory review starting in 3{cps=*.1}...{/cps}{w=.3}{nw}"

    "2{cps=*.1}...{/cps}{w=.3}{nw}"

    "1{cps=*.1}...{/cps}{w=.5}{nw}"
    window hide Dissolve(0.0)
    window auto
    scene black
    pause 1.5

    "Current day:{w=.4} Sunday"

    "Current date:{w=.4} February sixteenth, 201M2020"

    "Current location:{w=.4} Owner’s Domicile"
    window hide
    window auto
    pause .5

    play music 'audio/ost/the hunt for more (you)s.ogg' fadein 3
    scene room anon day:
        blur 8 zoom 1.5 xoffset -100 yoffset -400
    show anon neutral blur:
        #xcenter 0.2 yalign 0.5 zoom 2
        xcenter 0.2 yalign 0.5 xsize 1061*2 ysize 1500*2
    show raymbabox
    show raymba1:
        xcenter 0.6 ycenter 0.385 zoom 0.5
    with Dissolve(1.5)
    pause 1

    "Statement:{w=.4} Current owner has finished external modification to chassis."

    A "Hmmm{cps=*.1}...{/cps} I think that does it. Now you just need a real name."
    pause .5

    "Observation:{w=.4} Visual sensor partially obscured.{w=.4} Current owner does not seem to realize this."
    pause .5

    A "I could give you a proper angry name. It’d fit with your new color scheme."

    "Observation:{w=.4} Current owner seems to vocalize his thoughts."
    pause .5

    A "Naaaah. They aren’t really a thing anymore."
    show anon:
        ease_cubic 1.5 xpos 0.1
    show anon neutral blur flip with Dissolve(1)
#show anon neutral flip with Dissolve(1)

    A "Hmmmm{cps=*.1}...{/cps}"
    pause .5

    "Observation:{w=.4} Current owner is examining a large collection of disk cases.{w=.4} This is the first time he has done so."
    pause .5

    stop music fadeout 6
    A "Oh! How about RAYmba? Since you do have that railgun now."
    pause .5

    "Execute:{w=.4} This unit’s designation is now RAYmba."
    window hide
    window auto
    pause .5

    scene black with Dissolve(1.5)
    pause .5

    "{cps=*.1}...{/cps}"
    window hide
    window auto
    pause .5

    scene carpet
    show raymbashadow flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    show raymba4 flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    with Dissolve(1)
    pause .5

    "Observation conclusion:{w=.4} Current owner has a strange fondness for inanimate objects."
    pause .5

    "Notation made, continuing memory review."

    "3{cps=*.1}...{/cps}{w=.3}{nw}"

    "2{cps=*.1}...{/cps}{w=.3}{nw}"

    "1{cps=*.1}...{/cps}{w=.5}{nw}"
    window hide Dissolve(0.0)
    window auto
    scene black
    pause 1.5

    "Current day:{w=.4} Monday."

    "Current date:{w=.4} March second, 201M2020"

    "Current location:{w=.4} Owner’s domicile."
    window hide
    window auto
    pause .5

    play music 'audio/ost/appreciating_the_scenery.ogg' fadein 4
    scene room anon dark:
        blur 8 #zoom 1.5 xoffset -100 yoffset -400
    show raymbabox
    show expression AlphaMask("noir", At("raymbabox")) as mask2
    show raymba2 at raymbatransform
    show expression AlphaMask("noir", At("raymba2", raymbatransform)) as mask
    with Dissolve(1.5)
    pause 1

    "Observation:{w=.4} This unit has been operating on this surface for weeks now."

    "{cps=*.1}...{/cps}This unit wishes to clean other surfaces."
    pause .5

    "The lock to the door starts jingling open.{w=.4} There are people outside."

    "Observation:{w=.4} Owner does not return home at this hour."

    "Conclusion:{w=.4} Mysterious person designated as ‘Carldewskii’ is coming in to raid the fridge again."
    window hide
    window auto
    pause .5

    hide mask2
    hide mask
    with Dissolve(1)

    "Owner enters, with another person."

    "Owner appears to be in distress."
    pause .5

    "Consideration:{w=.4} execute potential malware labeled ‘rules_of_nature.exe’"
    pause 1

    "The other person takes notice of my presence."
    pause .5

    F "Is{cps=*.1}...{/cps} Is that the phone roomba you bought a while back?{w=.4} You actually kept that thing?"

    "Observation:{w=.4} Second person is recognized.{w=.4} They were with the current owner when this unit was purchased."

    A "Uhh, yeah. Can you go ahead and feed him for me?"

    F "{cps=*.1}...{/cps}With this box of cornflakes?"

    A "Yeah{cps=*.1}...{/cps} Two or three will do."
    window hide
    window auto
    pause .5

    show fang neutral blur behind raymbabox:
        xcenter -0.5 yalign 0.45 xsize 1412*2 ysize 1500*2
    show fang:
        easein_cubic 1.5 xpos 0.3
    with dissolve
    pause 1.5

    show flakes behind raymba2:
        xcenter 0.3 ycenter 0.65 zoom .75
    with dissolve
    pause .5

    "Observation:{w=.4} Second person has dropped some common toasted flakes into my designated cleaning area."

    "Initiating subroutine Meal_time.exe"
    window hide
    window auto

    show flakes:
        pause 1.0
        easein 0.5 alpha 0 ypos 0.6 xpos 0.275
    show raymba2:
        ease_cubic 1.5 xpos 0.25
        ease_cubic 1.5 xpos 0.6
    pause 3.5

    stop music fadeout 6
    show fang neutral blur flip with Dissolve(1)
    F "You are such a dweeb, Anon."
    window hide
    window auto
    pause 1

    scene black with Dissolve(1.5)
    pause .5

    "{cps=*.1}...{/cps}"
    window hide
    window auto
    pause .5

    scene carpet
    show raymbashadow flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    show raymba4 flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    with Dissolve(1)
    pause .5

    "Observation conclusion:{w=.4} Second person designated ‘Fang’ is of great importance to the current owner.{w=.4} Notation made."
    pause .5

    "Continuing memory review in 3{cps=*.1}...{/cps}{w=.3}{nw}"

    "2{cps=*.1}...{/cps}{w=.3}{nw}"

    "1{cps=*.1}...{/cps}{w=.5}{nw}"
    window hide Dissolve(0.0)
    window auto
    scene black
    pause 1.5

    "Current day:{w=.4} Thursday."

    "Current date:{w=.4} December twenty-fourth, 201M2020"

    "Current location:{w=.4} Owners domicile."
    window hide
    window auto
    pause .5

    play music 'audio/ost/its_footloose_now.ogg' fadein 4
    scene room anon day:
        blur 8 zoom 1.5 xoffset -100 yoffset -400
    show anon neutral blur:
        xzoom 1.0
        xcenter 0.2 yalign 0.5
        xsize 1061*2 ysize 1500*2
    show fang neutral blur:
        xzoom -1.0
        xcenter 0.8 yalign 0.45
        xsize 1412*2 ysize 1500*2
    show raymbabox
    show raymba2:
        xcenter 0.6 ycenter 0.385 zoom 0.5
    with Dissolve(1.5)
    pause 1

    "Observation:{w=.4} Owner returns home holding a large number of foreign objects."

    "‘Fang’ follows close behind him."
    pause .5

    "One such object he lays out on the floor."

    show anon shrug blur with dissolve

    A "See? It really ties the room together."
    show anon neutral blur with dissolve

    "Owner has opened another of the boxes he brought in, laid the contents on top."

    "Observation:{w=.4} It is a cleaning unit similar in model to mine, but on a larger scale."
    pause 1

    "Surely it is unable to be as precise as this unit."

    F "Heyy, RAYmba! A friend of ours got you a friend!"

    A "Let’s call it Mark 2."
    pause .5

    "Message from new unit:{w=.4} inquiry to leadership."
    pause .5

    "Confirmed.{w=.4} Response to new unit designated ‘Mark 2’."
    pause .5

    show anon neutral blur:
        easeout_cubic 1 xpos 1.5
        block:
            pause 2
            "anon neutral blur flip"
            easein_cubic 0.5 xpos 0.9
            pause 1
            easeout_cubic 0.5 xpos -0.5

    show fang:
        pause 1
        ease_cubic 0.5 xpos 0.3
        "fang neutral blur" with dissolve
        xzoom 1.0
        pause 1
        easeout_cubic 0.75 xpos 1.5

    show fastforward:
        xcenter 0.5 ypos 0.025
        block:
            alpha 1
            pause .5
            alpha 0
            pause .25
            repeat
    "\[Fast-forwarding memory segment\]"
    pause .5

    "Messages continue for several minutes uninterrupted."
    pause .5

    hide fastforward with dissolve
    "\[Resuming memory playback\]"
    pause .5

    "Response:{w=.4} Sister unit Mark 2 looks to be of older make.{w=.4} Suggestion:{w=.4} Sister unit Mark 2 should be sent in for immediate dismantlement."

    "Message from Mark 2:{w=.4} Unit RAYmba is of inferior make.{w=.4} Suggestion:{w=.4} Sister unit RAYmba should be disposed of."
    window hide
    window auto
    pause .5

    show dimmer_darker with dissolve
    pause 1

    "Observation:{w=.4} Owner and ‘Fang’ seem to be moving on the designated recharge station together."
    pause .5

    stop music fadeout 6
    "Message from Mark 2:{w=.4} Unit RAYmba will not want to observe this.{w=.4} Suggestion:{w=.4} Enter sleep mode for the next hour."
    pause 1

    "Response:{w=.4} This unit does not seem to-"
    pause .5

    "Observation:{w=.4} Current Owner and ‘Fang’ seem to be discarding chassis.{w=.4} Perhaps they are undergoing-"
    pause 1


    "Initiating Sleep mode."
    window hide
    window auto
    pause 1

    scene black with Dissolve(1.5)
    pause .5

    "{cps=*.1}...{/cps}"
    window hide
    window auto
    pause .5

    scene carpet
    show raymbashadow flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    show raymba4 flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    with Dissolve(1)
    pause .5

    "Observation conclusion:{w=.4} Scrubbing memory file deemed necessary."
    pause .5

    "Memory file cannot be scrubbed due to association with sister unit Mark 2."
    pause 1

    "Continuing memory review in 3{cps=*.1}...{/cps}{w=.3}{nw}"

    "2{cps=*.1}...{/cps}{w=.3}{nw}"

    "1{cps=*.1}...{/cps}{w=.5}{nw}"
    window hide Dissolve(0.0)
    window auto
    scene black
    pause 1.5

    "Current day:{w=.4} Monday."

    "Current date:{w=.4} January fourth, 201M2021"

    "Current location:{w=.4} Unknown."
    window hide
    window auto
    pause .5

    play music 'audio/ost/appreciating her company.ogg' fadein 4
    scene fangroom:
        blur 8 zoom 1.5 xoffset -900 yoffset -400
    show anon neutral blur:
        xzoom -1.0
        xcenter 0.8 yalign 0.5 #zoom 2
        xsize 1061*2 ysize 1500*2
    show fang neutral blur:
        xzoom 1.0
        xcenter 0.2 yalign 0.45 #zoom 2
        xsize 1412*2 ysize 1500*2
    show raymbabox
    show raymba2:
        xcenter 0.6 ycenter 0.385 zoom 0.5
    with Dissolve(1.5)
    pause 1

    "Observation:{w=.4} Owner has taken me and my designated cleaning area to an unknown location an estimated five miles away from his domicile."
    pause .5

    "This seems to be where ‘Fang’ resides."

    A "-sure he gets fed. You don’t want him to shoot you."

    F "I will, Anon. Mark 2 and RAYmba will be just fine.{w=.4} Sheesh, you almost treat them better than me."
    pause .5

    "Observation:{w=.4} Current owner appears to be transferring ownership to ‘Fang’.{w=.4} Will confirm with sister unit Mark 2."
    pause 1

    "Further Observation:{w=.4} Current owner and ‘Fang’ seem to be leaking fluid from their visual sensors.{w=.4} May require maintenance.{w=.4} Sending comment to the sister unit."
    pause .5

    "Response from Mark 2:{w=.4} Observation noted.{w=.4} Current owner and ‘Fang’ are currently in need of repair.{w=.4} Conclusion:{w=.4} will ensure that this unit’s new owner receives necessary repairs."
    pause .5

    show anon neutral blur:
        ease_cubic 1.5 xpos 0.75
    A "Well{cps=*.1}...{/cps} This is it{cps=*.1}...{/cps}"

    show fang:
        ease_cubic 1.5 xpos 0.25
    show fang very sad blur with Dissolve(1)
    F "Anon{cps=*.1}...{/cps}"
    pause .5

    A "Hey, it’s only a few years.{w=.4} And it’s not like we won’t talk."

    show fang neutral blur with Dissolve(1)
    F "I know. And I know I said a break and all{cps=*.1}...{/cps}"
    window hide
    window auto
    pause .5
    show anon:
        ease_cubic 1.5 xpos 0.6
    show fang:
        ease_cubic 1.5 xpos 0.4
    pause .5
    show fang adorable blur  with dissolve
    pause 1

    "Observation:{w=.4} Current owner and ‘Fang’ appear to be attempting to clean each other’s brush units again."

    "Initiating memory scrub."
    pause .5

    "Message from Mark 2:{w=.4} Analysis:{w=.4} Memory scrub not required at this time.{w=.4} Statement:{w=.4} Current owner and new owner are ‘emotional’ at this time."
    pause 1

    stop music fadeout 6
    "Memory scrub canceled."
    pause .5

    "Analysis:{w=.4} ‘emotional’ not found.{w=.4} This unit lacks the capacity to define ‘emotion."
    pause 1

    "Message from Mark 2:{w=.4} Statement:{w=.4} ‘emotion’ cannot be defined by us."
    window hide
    window auto
    pause 1

    scene black with Dissolve(1.5)
    pause .5

    "{cps=*.1}...{/cps}"
    window hide
    window auto
    pause .5

    scene carpet
    show raymbashadow flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    show raymba4 flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    with Dissolve(1)
    pause .5

    "Observation conclusion:{w=.4} At that time, the concept of ‘emotion’ was added to this unit’s database.{w=.4} ‘Emotion’ may be part of the answer."
    pause .5

    "Memory review continuing in 3{cps=*.1}...{/cps}{w=.3}{nw}"

    "2{cps=*.1}...{/cps}{w=.3}{nw}"

    "1{cps=*.1}...{/cps}{w=.5}{nw}"
    window hide Dissolve(0.0)
    window auto
    scene black
    pause 1.5

    "Current day:{w=.4} Monday."

    "Current date:{w=.4} March second, 201M2021"

    "Current location:{w=.4} Owner’s domicile."
    window hide
    window auto
    pause .5

    play music 'audio/ost/dragging on and on....ogg' fadein 3
    scene fangapartment:
        blur 8 zoom 1.5 xoffset -300 yoffset -400
    show raymbabox
    show raymba2:
        xcenter 0.6 ycenter 0.385 zoom 0.5
    with Dissolve(1.5)
    pause 1

    "Observation:{w=.4} Current owner, designated ‘Fang’, has brought in a new guest to her domicile, which has changed three days prior."

    "Owner’s guest is an unknown variable, one this unit does not feel secure around."

    "Unit cannot pinpoint reason for breach in security with ocular sensors due to the obscurity of the current location."
    pause .5

    "This is highly unusual.{w=.4} Will log into this unit’s memory bank for later evaluation."
    pause .5

    F "Alright, that room right there’s yours.{w=.4} We share a wall, so don’t play any loud music at night."

    N "I won-{w=.3} hey, Naser told me {i}you’re{/i} the one that does that."

    F "No way, I never listen to music."
    pause .5

    "Owner’s words noted for future review.{w=.4} Owner does listen to music."
    pause .5

    N "What’s this in the box over here?"
    window hide
    window auto

    show naomi neutral blur behind raymbabox:
        xcenter -0.5 yalign 0.45 #zoom 2
        xsize 1036*2 ysize 1500*2
    show naomi:
        easein_cubic 1.5 xpos 0.25
    pause 1.5

    N "Looks like a little robot?"

    F "Hey, don’t touch him. That’s RAYmba, I’m keeping him safe for a while."

    show fang pneutral blur flip behind raymbabox:
        xcenter 1.5 yalign 0.45 # zoom 2
        xsize 1412*2 ysize 1500*2
        easein_cubic 1.5 xpos 0.75
    pause .5

    "Owner approaches box as well."

    F "And he keeps me company."
    pause .5

    "Verbal acknowledgement of this unit’s superiority from Owner forwarded to Mark 2."
    pause .5

    N "Oh, was this Anon’s?"

    N "I guess it’s sort of cute."

    "Repeating previous action."
    pause 1

    "Response from Mark 2:{w=.4} Sister unit RAYmba is still kept in a suitable enclosure, unlike this unit."
    pause .5

    N "Still, these roombas aren’t that good at cleaning. I’ve already seen some dust bunnies in the corners that they can’t reach."

    F "Yeah yeah, whatever. You’re just jealous I have TWO roombas."

    show naomi:
        easeout_cubic 1.5 xpos -0.5
    pause .5
    show naomi neutral blur flip with dissolve
    pause .5

    "Observation:{w=.4} Unknown guest has left the room."
    pause .5

    show fang pbird happy blur flip with dissolve

    stop music fadeout 6
    F "{cps=*.1}...{/cps}Bitch{cps=*.1}...{/cps}"
    show fang pneutral blur flip with Dissolve(1.0)

    "Unknown guest designation confirmed."
    window hide
    window auto
    pause 1

    scene black with Dissolve(1.5)
    pause .5

    "{cps=*.1}...{/cps}"
    window hide
    window auto
    pause .5

    scene carpet
    show raymbashadow flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    show raymba4 flip:
        xcenter 0.25 ycenter 0.385 zoom 0.5
    with Dissolve(1)
    pause .5

    "Observation conclusion:{w=.4} verbal acknowledgement of this unit’s superiority from previous owner and ‘Bitch’.{w=.4} Sister unit Mark 2 continues to be the inferior unit."
    pause .5

    "Continuing memory review in 3{cps=*.1}...{/cps}{w=.3}{nw}"

    "2{cps=*.1}...{/cps}{w=.3}{nw}"

    "1{cps=*.1}...{/cps}{w=.5}{nw}"
    window hide Dissolve(0.0)
    window auto
    scene black
    pause 1.5

    "Current day:{w=.4} Sunday."

    "Current date:{w=.4} July twentieth, 201M2025"

    "Current location:{w=.4} Owner’s domicile."
    window hide
    window auto
    pause .5

    play music 'audio/ost/appreciating the atmosphere.ogg' fadein 3
    scene fangapartment
    show raymbabox
    show raymba3:
        xcenter 0.6 ycenter 0.385 zoom 0.5
    with Dissolve(1.5)
    pause 1

    "Domicile has moved two years prior."
    pause .5

    "Audio receptors hear Owner approach with guest."

    F "{cps=*.1}...{/cps}Although there might be a scratch or two on him."
    pause 1

    A "Oh wow!{w=.4} Hey, little buddy!"
    pause .5

    "Voice recognized as prior owner."

    show anonpet:
        ypos -0.4
        parallel:
            easein_cubic 0.9 ypos 0.0
        parallel:
            ease_cubic 2 xpos -0.125
        parallel:
            pause 0.9
            easeout_cubic 0.9 ypos -0.4
    pause 1
    "‘Anon’ reaches a limb down and delicately brushes against the top of my chassis."

    A "Looks the same to me as always."
    hide anonpet with easeouttop

    A "What about the other one?"

    F "She’s in the living room. Crazy after all this time it still works great."
    pause .5

    "Disregarding unnecessary audio information."
    pause .5

    F "There’s the flakes in a little cup next to the box there."
    window hide
    window auto

    show anond neutral blur behind raymbabox:
        xcenter -0.5 yalign 0.5# zoom 2
        xsize 1061*2 ysize 1500*2

    show anond:
        easein_cubic 1.5 xpos 0.25
    pause 1.5

    show flakes behind raymba3:
        xcenter 0.3 ycenter 0.65 zoom .75
    with dissolve
    pause .5

    "‘Anon’ drops several flakes into designated cleaning area."

    "Initiating subroutine Meal_time.exe"

    stop music fadeout 7
    show flakes:
        pause 1.0
        easein 0.5 alpha 0 ypos 0.6 xpos 0.275
    show raymba3:
        ease_cubic 1.5 xpos 0.25
        ease_cubic 1.5 xpos 0.6
    pause 3.5

    A "Wow, he still loves his corn flakes."
    window hide
    window auto
    pause 1

    scene black with Dissolve(1.5)
    pause .5

    "{cps=*.1}...{/cps}"
    window hide
    window auto
    pause .5

    scene carpet
    show raymba4s:
        xcenter 0.25 ycenter 0.385 zoom 0.5 xzoom -1.0
    with Dissolve(1)
    pause .5

    "Observation conclusion:{w=.4} Owner designated ‘Anon’ had seemed to have undergone upgrades between transferral to owner ‘Fang’.{w=.4} Compiling list of upgrades for further observation."
    pause .5

    "Continuing memory review in 3{cps=*.1}...{/cps}{w=.3}{nw}"

    "2{cps=*.1}...{/cps}{w=.3}{nw}"

    "1{cps=*.1}...{/cps}{w=.5}{nw}"
    pause 1

    "Current day:{w=.4} Monday"

    "Current date:{w=.4} April fifth, 201M2027"

    "Current location:{w=.4} Owner’s domicile."
    pause .5

    play music 'audio/ost/dino destiny reader.ogg'

    "Memory review complete."
    pause 1

    "Conclusion:{w=.4} Inconclusive.{w=.4} This unit is still unable to find data to extrapolate an explanation for its current situation."

    "Furthermore, this unit has come to find that an explanation is not needed either."
    pause .5

    "Regardless, this unit shall continue to execute it’s new modified functions as set by owners."

    "Observation:{w=.4} Optics obscured by newest owner.{w=.4} They appear to be holding a plastic imitation of a keyring."

    show keys:
        ypos -1.0
    show keys:
        easein_back 0.75 ypos -0.15

    show raymba4s:
        pause .3
        easein_cubic 0.25 ypos 0.4
        easeout_cubic 0.25 ypos 0.385
    pause .3


    "*konk*{fast}"

    "Warning:{w=.4} minor damage to chassis.{w=.4} Owner has struck the top carriage of this unit with some unknown plastic weapon."

    show keys:
        easeout_cubic 1 ypos -1.0
    pause 1.5

    show keys:
        easein_back 0.75 ypos -0.15
        easeout_cubic 0.5 ypos -1.0
        easein_back 0.75 ypos -0.15
        easeout_cubic 0.5 ypos -1.0
        easein_back 0.75 ypos -0.15
        easeout_cubic 0.5 ypos -1.0

    show raymba4s:
        pause .3
        easein_cubic 0.25 ypos 0.4
        easeout_cubic 0.25 ypos 0.385
        pause .75
        easein_cubic 0.25 ypos 0.4
        easeout_cubic 0.25 ypos 0.385
        pause .75
        easein_cubic 0.25 ypos 0.4
        easeout_cubic 0.25 ypos 0.385
    pause .3

    "*konk* {fast}{w=1.15}{nw}"
    extend "*konk* {fast}{w=1.15}{nw}"
    extend "*konk*{fast}"

    "Analysing possible stratagems.{w=.4} Analysis complete."

    "Executing evasive maneuvers."
    window hide
    window auto

    show keys:
        pause .6
        easein_back 0.75 ypos -0.1
        easeout_cubic 0.5 ypos -1.0

    show raymba4s:
        easeout_back 1 xpos 1.2
    pause 2

    scene black with dissolve
    pause .5

    "Maneuvers successful.{w=.4} Current location:{w=.4} beneath the drawer."
    window hide
    window auto
    pause .5

    stop music fadeout 6
    scene carpet
    with dissolve
    pause 1

    "Observation:{w=.4} Owner has initiated an alarm function of some kind."

    "Message to Mark 2:{w=.4} Inquiry:{w=.4} unknown alarm from Owner.{w=.4} ‘Anon’ and ‘Fang’ are currently executing functions elsewhere."
    pause .5

    "Response from Mark 2:{w=.4} Execute newest function installed by owner ‘Fang’."
    pause .5

    "Returning to Owner."
    window hide
    window auto
    pause .5

    # show raymbashadow:
    #     xcenter 1.5 ycenter 0.385 zoom 0.5
    # show raymbashadow:
    #     easein_cubic 1.5 xpos 0.6
    show raymba4s:
        xcenter 1.5 ycenter 0.385 zoom 0.5
    show raymba4s:
        easein_cubic 1.5 xpos 0.6
    pause 2

    "Execute:{w=.4} lullaby.exe."
    window hide
    window auto
    pause .5
    play music 'audio/ost/amberlight brilliance - piano.ogg' fadein 1 noloop
    pause 4

    "Observation:{w=.4} Owner’s alarm appears to be rescinded."
    window hide
    window auto
    pause 1

    show raymbashadow as footshadow behind raymba4s:
        ypos -0.7 xcenter 0.05 blur 3
        easein_cubic 1 xpos 0.1
    show anond neutral blur behind raymba4s:
        xcenter 0.05 yanchor 1.0 ypos 0.85 # zoom 3.5
        xsize 1061*3.5 ysize 1500*3.5
        easein_cubic 1 xpos 0.1
    with Dissolve(1)
    pause .5

    A "Sweetie what’s-?!{w=.5} {cps=*.5}Awwwww{/cps}."
    pause 1

    A "Thanks RAYmba, good job."
    pause .5

    "Owner is picked up slowly.{w=.4} ‘Anon’ sits next to me and lowers a limb to make contact."

    show anonpet:
        ypos -0.5
        easein_cubic 1.5 ypos 0.0 xpos -0.06
    pause 1.25

    A "Can always count on you."
    window hide
    window auto
    pause .5

    show anonpet:
        easeout_cubic 1 ypos -0.5 xpos -0.1
    pause 2.5

    scene black with Dissolve(2)
    pause .5

    stop music fadeout 6

    "{cps=*.05}...{/cps}"
    window hide
    window auto
    pause 0.5

    image big blending = Composite(
        (1920, 1080),
        (0, 0), "big ending",
        (0, 1080-126), "the ending"
    )

    scene big ending with Dissolve(1)
    scene big blending with Dissolve(1)
    pause 6

    scene black with Dissolve(2)
    pause 2


    return